[gentoo-commits] repo/gentoo:master commit in: net-wireless/gr-osmosdr/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     7572f95b8cdc8dfae8a302af446c7f4b1481dcc5
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 18 17:50:46 2022 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Thu Aug 18 17:50:46 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7572f95b

net-wireless/gr-osmosdr: add 0.2.3_p20210128

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 net-wireless/gr-osmosdr/Manifest                   |  1 +
 .../gr-osmosdr/gr-osmosdr-0.2.3_p20210128.ebuild   | 77 ++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/net-wireless/gr-osmosdr/Manifest b/net-wireless/gr-osmosdr/Manifest
index 436343f9a5f7..0eba2d41db44 100644
--- a/net-wireless/gr-osmosdr/Manifest
+++ b/net-wireless/gr-osmosdr/Manifest
@@ -1 +1,2 @@
 DIST gr-osmosdr-0.2.3.tar.gz 252727 BLAKE2B 04fe86496c09a274058bfd812fc14d7843d7e9db2648cf2cf5292e50494a859e22b1ab211f7078f2b6964c786c5f5ad5c3c9d2dd44ec5fc96d240b96f2cb63f4 SHA512 3c82a39972a309aa5b023b9c5e61f1fc80b797380b7a6c6c23cd4fe278cfaba3ab3019f32d38ebc01300868bb892f6aaaa7f12c9ee9b7ab5ba3e38817a40bf3e
+DIST gr-osmosdr-0.2.3_p20210128.tar.gz 257938 BLAKE2B 1bdb3b57ec6a2f942769770c34d41b4e3db5b62f8c337d724b0099f9a2fe5bdb7231bc0727dfe4bd01cd62918b4847ea2f8780208c0960bced5853c716ec6f02 SHA512 4dcb6b2c10eeb2252111ba691be179fe5b6dc9598fa7e6129a3b214ee74d43ca2d67ab5eafa73cea2abb25729c24be0592585d149e13c7285f2ce330e52a6470

diff --git a/net-wireless/gr-osmosdr/gr-osmosdr-0.2.3_p20210128.ebuild b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.3_p20210128.ebuild
new file mode 100644
index 000000000000..518b27caa2a1
--- /dev/null
+++ b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.3_p20210128.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="GNU Radio source block for OsmoSDR and rtlsdr and hackrf"
+HOMEPAGE="http://sdr.osmocom.org/trac/wiki/GrOsmoSDR"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/osmocom/gr-osmosdr.git"
+else
+	COMMIT="a100eb024c0210b95e4738b6efd836d48225bd03"
+	SRC_URI="https://github.com/osmocom/gr-osmosdr/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+IUSE="airspy bladerf hackrf iqbalance python rtlsdr sdrplay soapy uhd xtrx"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/boost:=
+	dev-libs/log4cpp
+	>=net-wireless/gnuradio-3.9.0.0:0=[${PYTHON_SINGLE_USEDEP}]
+	sci-libs/volk:=
+	airspy? ( net-wireless/airspy )
+	bladerf? ( >=net-wireless/bladerf-2018.08_rc1:= )
+	hackrf? ( net-libs/libhackrf:= )
+	iqbalance? ( net-wireless/gr-iqbal:=[${PYTHON_SINGLE_USEDEP}] )
+	rtlsdr? ( >=net-wireless/rtl-sdr-0.5.4:= )
+	sdrplay? ( net-wireless/sdrplay )
+	soapy? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:=[${PYTHON_SINGLE_USEDEP}] )
+	xtrx? ( net-wireless/libxtrx )
+	"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_FILE=ON
+		-DENABLE_AIRSPY="$(usex airspy ON OFF)"
+		-DENABLE_BLADERF="$(usex bladerf ON OFF)"
+		-DENABLE_HACKRF="$(usex hackrf ON OFF)"
+		-DENABLE_IQBALANCE="$(usex iqbalance ON OFF)"
+		-DENABLE_PYTHON="$(usex python ON OFF)"
+		-DENABLE_RTL="$(usex rtlsdr ON OFF)"
+		-DENABLE_RTL_TCP="$(usex rtlsdr ON OFF)"
+		-DENABLE_SDRPLAY="$(usex sdrplay ON OFF)"
+		-DENABLE_NONFREE="$(usex sdrplay ON OFF)"
+		-DENABLE_SOAPY="$(usex soapy ON OFF)"
+		-DENABLE_UHD="$(usex uhd ON OFF)"
+		-DENABLE_XTRX="$(usex xtrx ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if use python; then
+		find "${D}" -name '*.py[oc]' -delete || die
+		python_fix_shebang "${ED}"/usr/bin
+		python_optimize
+	fi
+	mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${P}"
+}