[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     4aed2cdea131ecc22c20d52ebca80594e514d139
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  7 02:23:10 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Aug  7 02:24:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4aed2cde

net-misc/gnome-remote-desktop: Version bump to 42.4

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-42.4.ebuild               | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index e0fcfb6aa286..591902abeda8 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-42.3.tar.xz 165424 BLAKE2B 43ff645dfcc75d0c97ab43840631f3c47337ed89c848fa65fb6c23b74f4ab2b9ada383c1cf17592e6a9382aac28f008d34c06d90f341731d1221ac86182ac666 SHA512 3545ec6b3f7f80315546d03ecb0c30ed554e879c743e1d7031ac65cf10e6d9d510553049393221be0be203a79b8be8bc96c0d3fe600be1ac3c0a1e24431ba945
+DIST gnome-remote-desktop-42.4.tar.xz 165500 BLAKE2B c1221d5aa91fcbc5c6defd902674f210e9132495202659dbacffcb7da17042a2ad73d938a147c63a77e822b34dfee9300226fd0180e321b3087057c7e2365268 SHA512 dc040e216c7cff4a2f95d706d7916489ba0a871dff502fbc5ef81d374f7ea1edc32286d32ad07f961a3bc55b353663e72296042b61837c3479fc929bd1253d98

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.4.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.4.ebuild
new file mode 100644
index 000000000000..b7ff4b497493
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-42.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org gnome2-utils meson python-any-r1 systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	>=dev-libs/glib-2.68:2
+	>=media-video/pipewire-0.3.0:=
+	app-crypt/libsecret
+	x11-libs/libnotify
+	media-libs/libepoxy
+	x11-libs/libdrm
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.5.0:=[server]
+		>=sys-fs/fuse-3.9.1
+		>=x11-libs/libxkbcommon-1.0.0
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}