[gentoo-commits] repo/gentoo:master commit in: app-text/bibletime/

["Marek Szuba" <marecki@gentoo.org>]

commit:     9f7fac0f5308fb6b392cab6e823b9da1de504cf5
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 25 21:39:17 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Mon Jul 25 22:15:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9f7fac0f

app-text/bibletime: fix DEPEND

Having checked the documentation dev-libs/icu should indeed be a
run-time dependency as well, and dev-qt/linguist-tools belongs in
BDEPEND.

Closes: https://bugs.gentoo.org/861044
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-text/bibletime/bibletime-3.0.3-r1.ebuild | 59 ++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/app-text/bibletime/bibletime-3.0.3-r1.ebuild b/app-text/bibletime/bibletime-3.0.3-r1.ebuild
new file mode 100644
index 000000000000..3cb15a25d576
--- /dev/null
+++ b/app-text/bibletime/bibletime-3.0.3-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt Bible-study application using the SWORD library"
+HOMEPAGE="https://bibletime.info/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=app-text/sword-1.8.1
+	dev-cpp/clucene
+	dev-libs/icu
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebchannel:5
+	dev-qt/qtwebengine:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-qt/qttest:5
+	net-misc/curl
+	sys-libs/zlib"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( ChangeLog README.md )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "s:Dictionary;Qt:Dictionary;Office;TextTools;Utility;Qt:" \
+		-i cmake/platforms/linux/bibletime.desktop.cmake || die "fixing .desktop file failed"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_HANDBOOK_HTML=no
+		-DBUILD_HANDBOOK_PDF=no
+		-DBUILD_HOWTO_HTML=no
+		-DBUILD_HOWTO_PDF=no
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}