[gentoo-commits] repo/gentoo:master commit in: www-apps/radarr/

["Craig Andrews" <candrews@gentoo.org>]

commit:     54c0ec006ddcface2f28cc3e71a75668223c1727
Author:     Craig Andrews <candrews <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 11 13:22:34 2022 +0000
Commit:     Craig Andrews <candrews <AT> gentoo <DOT> org>
CommitDate: Mon Jul 11 13:28:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54c0ec00

www-apps/radarr: Delete libcoreclrtraceptprovider.so

Remove dependency on dev-util/lttng-ust

Closes: https://bugs.gentoo.org/857513
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org>

 www-apps/radarr/radarr-4.1.0.6175-r1.ebuild | 56 +++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/www-apps/radarr/radarr-4.1.0.6175-r1.ebuild b/www-apps/radarr/radarr-4.1.0.6175-r1.ebuild
new file mode 100644
index 000000000000..dbfdaf894fae
--- /dev/null
+++ b/www-apps/radarr/radarr-4.1.0.6175-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+SRC_URI="
+	amd64? ( https://github.com/Radarr/Radarr/releases/download/v${PV}/Radarr.master.${PV}.linux-core-x64.tar.gz )
+	arm? ( https://github.com/Radarr/Radarr/releases/download/v${PV}/Radarr.master.${PV}.linux-core-arm.tar.gz )
+	arm64? ( https://github.com/Radarr/Radarr/releases/download/v${PV}/Radarr.master.${PV}.linux-core-arm64.tar.gz )
+"
+
+DESCRIPTION="A fork of Sonarr to work with movies a la Couchpotato"
+HOMEPAGE="https://www.radarr.video"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="bindist strip test"
+
+RDEPEND="
+	acct-group/radarr
+	acct-user/radarr
+	media-video/mediainfo
+	dev-libs/icu
+	dev-util/lttng-ust:0
+	dev-db/sqlite"
+
+QA_PREBUILT="*"
+
+S="${WORKDIR}/Radarr"
+
+src_prepare() {
+	default
+
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so Radarr.Update/libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${PN}.init" ${PN}
+
+	keepdir /var/lib/${PN}
+	fowners -R ${PN}:${PN} /var/lib/${PN}
+
+	insinto /etc/logrotate.d
+	insopts -m0644 -o root -g root
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	dodir  "/opt/${PN}"
+	cp -R "${S}/." "${D}/opt/radarr" || die "Install failed!"
+
+	systemd_dounit "${FILESDIR}/radarr.service"
+	systemd_newunit "${FILESDIR}/radarr.service" "${PN}@.service"
+}