From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1416413-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 88840158095
for <garchives@archives.gentoo.org>; Fri, 8 Jul 2022 21:31:29 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id ADE4AE0DDA;
Fri, 8 Jul 2022 21:31:28 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 7ED6EE0DDA
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jul 2022 21:31:28 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 69812340D0C
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jul 2022 21:31:27 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id B0560529
for <gentoo-commits@lists.gentoo.org>; Fri, 8 Jul 2022 21:31:25 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1657315872.af70704b966862e5918c092d637a1239cc30d345.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-text/poppler/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-text/poppler/Manifest app-text/poppler/poppler-22.07.0.ebuild
X-VCS-Directories: app-text/poppler/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: af70704b966862e5918c092d637a1239cc30d345
X-VCS-Branch: master
Date: Fri, 8 Jul 2022 21:31:25 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: c16547ce-c5c4-4938-8be2-38c5b2dfba4c
X-Archives-Hash: 708f0b5a3d753dc5236cb5ee1720cad5
commit: af70704b966862e5918c092d637a1239cc30d345
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 8 21:21:15 2022 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jul 8 21:31:12 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=af70704b
app-text/poppler: 22.07.0 version bump, 9999 fixup, no soversion bump
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
app-text/poppler/Manifest | 2 +
app-text/poppler/poppler-22.07.0.ebuild | 134 ++++++++++++++++++++++++++++++++
2 files changed, 136 insertions(+)
diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 0258caecbc77..56660dab8d9d 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,3 +1,5 @@
DIST poppler-22.05.0.tar.xz 1828628 BLAKE2B d1757893c841d35cbdeda493afea92046c447dfa0d519ab9a872a75fdb7edbb06bbde78b2e7d41757f5bbff8d1f46c81f7314dff8386d4d686ded4d2cc85d65e SHA512 629098793050f7a901c2a2cf1efcad83c58d26164cf94f4aa3985465f016a8875c62be4fb8ab8005ca00ef061402962e6d6c14eb611ce29f2d71d3ae83f24737
DIST poppler-22.06.0.tar.xz 1834980 BLAKE2B 6988480dc30f5fe67be0170f8f006bdb4d3e6b0e0ad8643aa6cbf4fe017d52d8747f108267a30aee5ec4567aa5d2fcc9ce9824fc4dac45a1d37291fa668c2dfe SHA512 79e1a1440a0903ea6238dcc7afc4ecdf1f8cc53af94ec5649f631fca568711d48a7ec4046fccb8520818420dc21e4ad1aaf602c22b13f9ce22f4d06edc83c8a3
DIST poppler-22.06.0.tar.xz.sig 833 BLAKE2B e2a842fac83b5c42713aa45072d8ea1de5219cbbc35d04142a902f569fc7c558cbda9a2379fde6f9f933b701fabe98f93de71a0676837b2a21104f919a097bc8 SHA512 b61f706e52c57209bb180fbe5a65e366e2a841743ac2c24fc0828dc4bab8ae52da12330e4694e8dade1e1963112fc7b01c0c1b30141be2b7c8c0cf2aaab059c5
+DIST poppler-22.07.0.tar.xz 1838796 BLAKE2B 401573c3bd1e4801ee331e97a3787c88c0c3f0a10ca59f234622cee22760cd18a566c952f94a1e7263294d6f43c34c861cf53bde59b4bd92f806efe136f92197 SHA512 d3d8a0f50ddcf2020bbbc3c21c6fcdd6f31b431d984622c2a4ae4986b82a14d79969d7113588ba5d9a672babe4dc01fe2f5e8d9ce73a9fbce14685220d914f02
+DIST poppler-22.07.0.tar.xz.sig 833 BLAKE2B a73cc36e0c1c20c4f55e4896ae8d880d62d458a0d256022cdac50e48c7993fbf617e9c4de704958d103fae1ccb619d6122a06d2b51e0389f15338d67e34cefdb SHA512 252c34d4f8b7b43255ea5371c35348ac2d3044860d850fd510213a4785c633e230f61aab06b706b173e8e3482c7028a433fccae982adc18681f0da2b6e2bed3d
diff --git a/app-text/poppler/poppler-22.07.0.ebuild b/app-text/poppler/poppler-22.07.0.ebuild
new file mode 100644
index 000000000000..cffe79567ee4
--- /dev/null
+++ b/app-text/poppler/poppler-22.07.0.ebuild
@@ -0,0 +1,134 @@
+# Copyright 2005-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+ SLOT="0/9999"
+else
+ VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/aacid.asc
+ inherit verify-sig
+
+ SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+ SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+ SLOT="0/122" # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+ media-libs/fontconfig
+ >=media-libs/freetype-2.8
+ sys-libs/zlib
+ cairo? (
+ dev-libs/glib:2
+ x11-libs/cairo
+ introspection? ( dev-libs/gobject-introspection:= )
+ )
+ curl? ( net-misc/curl )
+ jpeg? ( media-libs/libjpeg-turbo:= )
+ jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+ lcms? ( media-libs/lcms:2 )
+ nss? ( >=dev-libs/nss-3.19:0 )
+ png? ( media-libs/libpng:0= )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtxml:5
+ )
+ tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${COMMON_DEPEND}
+ cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+ boost? ( dev-libs/boost )
+"
+BDEPEND="
+ dev-util/glib-utils
+ virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+ BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-aacid )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+ "${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
+ "${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+ "${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+ cmake_src_prepare
+
+ # Clang doesn't grok this flag, the configure nicely tests that, but
+ # cmake just uses it, so remove it if we use clang
+ if tc-is-clang ; then
+ sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+ fi
+
+ if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+ sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+ -i CMakeLists.txt || die
+ else
+ einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+ fi
+}
+
+src_configure() {
+ xdg_environment_reset
+ local mycmakeargs=(
+ -DBUILD_GTK_TESTS=OFF
+ -DBUILD_QT5_TESTS=OFF
+ -DBUILD_CPP_TESTS=OFF
+ -DBUILD_MANUAL_TESTS=OFF
+ -DRUN_GPERF_IF_PRESENT=OFF
+ -DENABLE_BOOST="$(usex boost)"
+ -DENABLE_ZLIB=ON
+ -DENABLE_ZLIB_UNCOMPRESS=OFF
+ -DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+ -DUSE_FLOAT=OFF
+ -DWITH_Cairo=$(usex cairo)
+ -DENABLE_LIBCURL=$(usex curl)
+ -DENABLE_CPP=$(usex cxx)
+ -DWITH_JPEG=$(usex jpeg)
+ -DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+ -DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+ -DENABLE_CMS=$(usex lcms lcms2 none)
+ -DWITH_NSS3=$(usex nss)
+ -DWITH_PNG=$(usex png)
+ $(cmake_use_find_package qt5 Qt5Core)
+ -DWITH_TIFF=$(usex tiff)
+ -DENABLE_UTILS=$(usex utils)
+ -DENABLE_QT6=OFF
+ )
+ use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ # live version doesn't provide html documentation
+ if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+ # For now install gtk-doc there
+ insinto /usr/share/gtk-doc/html/poppler
+ doins -r "${S}"/glib/reference/html/*
+ fi
+}