[gentoo-commits] repo/proj/guru:master commit in: app-misc/fastfetch/

["Florian Schmaus" <flow@gentoo.org>]

commit:     e153d6c4277b5e801d48e28515d21f96a96b0a6b
Author:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
AuthorDate: Tue Jul  5 04:22:15 2022 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Tue Jul  5 04:22:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=e153d6c4

app-misc/fastfetch: add 1.5.6

Signed-off-by: Viorel Munteanu <ceamac.paragon <AT> gmail.com>

 app-misc/fastfetch/Manifest               |  1 +
 app-misc/fastfetch/fastfetch-1.5.6.ebuild | 96 +++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 5b2a0c5f0..c9c7f9eaf 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1 +1,2 @@
 DIST fastfetch-1.5.5.tar.gz 346289 BLAKE2B db6e321150429343a1660ea384b43a8a35a2bbf11cd6acdf9089f0d020059afa28cd4f42ac8d956974f8bb0cd6c3fe9750393ecb154f5449ab5d14a27057daaa SHA512 3c51ff0e82982bf1974b113709eacf323c5a4080a8292d4ffd4575b10cf8ddbd0a55bda57dcaec5bd61bebe4b4f16e6634fa067d01d8df5be0120b2b5f5f886c
+DIST fastfetch-1.5.6.tar.gz 346273 BLAKE2B 4fa12c32905e1c3ed2ab1ba91e52da95a87b8c2ac8ce96076dd81e43ac491b100c44260d83833f1da18bd4fcb6646d71ee0b81bd0841e57ad174d2b2344be594 SHA512 fcc9e7c7c0742167253dcf01a0cc2ff906fe24769e2e87f9110d2c18ea8657eb1d7477aeb87ea2c805acaebb703542d3c36546ae90a7da3d40a96815aabb32c7

diff --git a/app-misc/fastfetch/fastfetch-1.5.6.ebuild b/app-misc/fastfetch/fastfetch-1.5.6.ebuild
new file mode 100644
index 000000000..31e8aeeb4
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.5.6.ebuild
@@ -0,0 +1,96 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? (
+		media-gfx/chafa
+		media-gfx/imagemagick:=
+	)
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+pkg_setup() {
+	if use chafa && ! use imagemagick; then
+		elog "USE chafa depends on imagemagick, but that is currently disabled.  Enabling imagemagick"
+	fi
+
+	if use imagemagick || use chafa; then
+		export fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	else
+		export fastfetch_enable_imagemagick7=no
+	fi
+
+	if use imagemagick || use chafa; then
+		export fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	else
+		export fastfetch_enable_imagemagick6=no
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+	)
+
+	cmake_src_configure
+}