[gentoo-commits] repo/proj/guru:dev commit in: app-text/OCRmyPDF/

["Theo Anderson" <telans@posteo.de>]

commit:     2fca7460b00323be79f923caf6ff82e5d0f6c727
Author:     James Beddek <telans <AT> posteo <DOT> de>
AuthorDate: Mon Jul  4 11:59:54 2022 +0000
Commit:     Theo Anderson <telans <AT> posteo <DOT> de>
CommitDate: Mon Jul  4 11:59:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=2fca7460

app-text/OCRmyPDF: add 13.6.0

Signed-off-by: James Beddek <telans <AT> posteo.de>

 app-text/OCRmyPDF/Manifest               |  1 +
 app-text/OCRmyPDF/OCRmyPDF-13.6.0.ebuild | 58 ++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/app-text/OCRmyPDF/Manifest b/app-text/OCRmyPDF/Manifest
index 0d41e1813..625e70793 100644
--- a/app-text/OCRmyPDF/Manifest
+++ b/app-text/OCRmyPDF/Manifest
@@ -1,2 +1,3 @@
 DIST OCRmyPDF-13.4.3.tar.gz 7889740 BLAKE2B d107b83f0d66fe6d19cc22bf76851650cd75c79900eff2c1e68d02a15ffb875dfa97472f8a8e80fe7051a7a8d33b9729855277121ed2e204b50729b6171bde26 SHA512 301efe2492de00527cacb8640eea68bf3f5398ca53a932872f3c62ef85616fc45e2c08c662cb42cfca69c6e2b5debf8860b192421c4370e7191cea5dbc4bf32d
 DIST OCRmyPDF-13.4.6.tar.gz 7890082 BLAKE2B 5d1fe4a0147dc7ca5bf5d1468e6cb23b57d436b80ec60b3cec9af4b1768af10fb387b724975e0c5e83aaa79806d4ba7a984fcf1d78f8bfaf97f42edfefa20f81 SHA512 fedf17630af21e94e45373aec45966cca2baa8abaca604a2a6820a74e62cf115bad376234b69dffad1ab26e50d5b891b1255026262512b518547f133f12c33d5
+DIST OCRmyPDF-13.6.0.tar.gz 7897382 BLAKE2B e05df2c44b32c1de17e7352f821c4bfb86dffad1c5bbb3440fab09b5172ba0bae99de4fe93039cf70e56f901a1afc0659f06c8760fb6f1b12edb7658a9b0cb7e SHA512 d58b154dd6affd9ef69b1ff79b20daee7ac9021601a3db2b9d571410b179a826de09f4b68a4683724749856fd27e2cca608e150c94aeca8bfdbc8c4d11d22a20

diff --git a/app-text/OCRmyPDF/OCRmyPDF-13.6.0.ebuild b/app-text/OCRmyPDF/OCRmyPDF-13.6.0.ebuild
new file mode 100644
index 000000000..923bd29e7
--- /dev/null
+++ b/app-text/OCRmyPDF/OCRmyPDF-13.6.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit bash-completion-r1 distutils-r1 optfeature
+
+DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
+HOMEPAGE="https://github.com/ocrmypdf/OCRmyPDF"
+SRC_URI="https://github.com/ocrmypdf/OCRmyPDF/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="test" # Exhausts RAM
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	app-text/tesseract
+	app-text/unpaper
+	dev-python/cffi[${PYTHON_USEDEP}]
+	>=dev-python/coloredlogs-15.0.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20[${PYTHON_USEDEP}]
+	>dev-python/pdfminer-six-20200720[${PYTHON_USEDEP}]
+	>dev-python/pikepdf-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pillow-8.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/reportlab-3.5.66[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4[${PYTHON_USEDEP}]
+	>=media-gfx/img2pdf-0.3.0[${PYTHON_USEDEP}]
+	media-gfx/pngquant
+	media-libs/leptonica
+	virtual/python-cffi[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		~dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp misc/completion/ocrmypdf.bash "${PN,,}"
+	insinto /usr/share/fish/vendor_completions.d
+	doins misc/completion/ocrmypdf.fish
+}
+
+pkg_postinst() {
+	optfeature "JBIG2 support" media-libs/jbig2enc
+}