[gentoo-commits] repo/gentoo:master commit in: dev-python/aws-xray-sdk-python/

["Michał Górny" <mgorny@gentoo.org>]

commit:     a05fe24943a69a57b73a4ba37af649b6f1ecb691
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  1 04:17:26 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jul  1 06:53:52 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a05fe249

dev-python/aws-xray-sdk-python: Bump to 2.10.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/aws-xray-sdk-python/Manifest            |  1 +
 .../aws-xray-sdk-python-2.10.0.ebuild              | 79 ++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/dev-python/aws-xray-sdk-python/Manifest b/dev-python/aws-xray-sdk-python/Manifest
index d278745eebbf..1833c1b493af 100644
--- a/dev-python/aws-xray-sdk-python/Manifest
+++ b/dev-python/aws-xray-sdk-python/Manifest
@@ -1 +1,2 @@
+DIST aws-xray-sdk-python-2.10.0.gh.tar.gz 270819 BLAKE2B caed5f5b92bdc25e0006663838549c9e9a85474829cce03f612ef4b9a36fce38460606e000c65bb140f7250225426bece2e8bc624a430bdfdcd4fc8808842aac SHA512 f5b4d08f5876cab2e833a763b1da52b6de1e3ca2c746b234a1b013f674155ec31686a6710225e411458f27ca096f68ee6413c8d1c360d5a326f1be94287d09b7
 DIST aws-xray-sdk-python-2.8.0.gh.tar.gz 267880 BLAKE2B 7a433a0b1b3ca38a100f3b23c79e9b0d7f84cb096f6d30832fdf16f171f9528aee8b81aaf3ba263a90d46f791de8b2f37a919651f9699e5fcf3073db83fc25b4 SHA512 e0fb3fb0bfbd963863714537ea12771df7ffa2857aaf4cdb6414d71ecdfc65c2623fa40a6a48c4eab30f4370d545a595db2762932133a6eba56121a4048502fb

diff --git a/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.10.0.ebuild b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.10.0.ebuild
new file mode 100644
index 000000000000..5cd390c0be9d
--- /dev/null
+++ b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.10.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="
+	https://github.com/aws/aws-xray-sdk-python/
+	https://pypi.org/project/aws-xray-sdk/
+"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.8.0-fix-py3.10-loops.patch"
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local EPYTEST_DESELECT=(
+		# Internet access
+		tests/test_patcher.py::test_external_file
+		tests/test_patcher.py::test_external_module
+		tests/test_patcher.py::test_external_submodules_full
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		# benchmark
+		tests/test_local_sampling_benchmark.py
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged deps
+		tests/ext/aiobotocore
+		tests/ext/pg8000
+		tests/ext/psycopg2
+		tests/ext/pymysql
+		tests/ext/pynamodb
+		tests/ext/sqlalchemy_core/test_postgres.py
+		tests/ext/django/test_db.py
+		# Internet access
+		tests/ext/httplib
+		tests/ext/requests
+		# requires old package vesions
+		tests/ext/django
+		tests/ext/aiohttp
+	)
+
+	epytest -p no:django
+}