[gentoo-commits] repo/gentoo:master commit in: dev-python/ini2toml/

["Michał Górny" <mgorny@gentoo.org>]

commit:     409b0481dd5d8baeaad109aac23735a14a7663b2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 25 04:50:18 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun 25 05:11:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=409b0481

dev-python/ini2toml: Add more test deps

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ini2toml/ini2toml-0.11-r1.ebuild | 51 +++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-python/ini2toml/ini2toml-0.11-r1.ebuild b/dev-python/ini2toml/ini2toml-0.11-r1.ebuild
new file mode 100644
index 000000000000..71e549fccc36
--- /dev/null
+++ b/dev-python/ini2toml/ini2toml-0.11-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Automatically conversion of .ini/.cfg files to TOML equivalents"
+HOMEPAGE="
+	https://pypi.org/project/ini2toml/
+	https://github.com/abravalheri/ini2toml/
+"
+SRC_URI="
+	https://github.com/abravalheri/ini2toml/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/packaging-20.7[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-0.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/configupdater[${PYTHON_USEDEP}]
+		dev-python/pyproject-fmt[${PYTHON_USEDEP}]
+		dev-python/tomli[${PYTHON_USEDEP}]
+		dev-python/tomlkit[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+EPYTEST_IGNORE=(
+	# validate_pyproject is not packaged
+	tests/test_examples.py
+)
+
+src_prepare() {
+	sed -i -e 's:--cov ini2toml --cov-report term-missing::' setup.cfg || die
+	distutils-r1_src_prepare
+}