[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     6cb7c1c2a2bf2e90aef4c5f373ba73f0e1b68a56
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 14 08:23:58 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jun 14 12:43:09 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6cb7c1c2

kde-plasma/plasma-firewall: 5.25.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.25.0.ebuild  | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 4aebb0d95ad6..7179a8489cd1 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
 DIST plasma-firewall-5.24.5.tar.xz 346660 BLAKE2B 767cd4722325e8035735b744afdccfe4114e68756919f3904fcbd2aa25879b09b7bb4fcaffcaf0a2687f5744e1177fb177658b6af0ed3fef7838498c99f583a3 SHA512 4c774b10c32929399a8b01007e3c34ab702803a0aa80ea812bbcc4d4ead02d0e64136f575454fdc2f0e938740afbf6d48025c654831aa5485b86253418bf13d1
+DIST plasma-firewall-5.25.0.tar.xz 355996 BLAKE2B 63e06d8d47c5e88cf2a57e1084a728d6bdbe5d444107cfd6bc579e65e76530fd48a1d1cf645a8b363e22d8dc086533ff870ad39c9839a31af0d417454c88d98f SHA512 d658278ae9c66380ea16e03598a789ec4f5ce120b41cc21f635e058aa672d08c94cc3bdb94ff9b60a91e42cc07ba7827c29fdf71197f2f2ef394c6a1661de0d8

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.25.0.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.25.0.ebuild
new file mode 100644
index 000000000000..152c543860af
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.25.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.94.0
+QTMIN=5.15.3
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}