[gentoo-commits] repo/gentoo:master commit in: dev-python/openapi-core/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     f6a8df2a7269d2d1b930fa462bf5388a0c160394
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 10 13:28:48 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Fri Jun 10 14:29:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f6a8df2a

dev-python/openapi-core: new package, add 0.14.2

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/openapi-core/Manifest                   |  1 +
 dev-python/openapi-core/metadata.xml               | 12 +++++
 dev-python/openapi-core/openapi-core-0.14.2.ebuild | 62 ++++++++++++++++++++++
 3 files changed, 75 insertions(+)

diff --git a/dev-python/openapi-core/Manifest b/dev-python/openapi-core/Manifest
new file mode 100644
index 000000000000..3d8678cf8eea
--- /dev/null
+++ b/dev-python/openapi-core/Manifest
@@ -0,0 +1 @@
+DIST openapi-core-0.14.2.gh.tar.gz 57519 BLAKE2B 06dfd284612ca11a271f075444db9b859ca5416e31594680d6b32abec1fe917105f213209d1bfcb9664b265ea3d62839579134e8e104754075cd692d1ba7a99a SHA512 19a2508d56053214993abed7d173d17b55a80dac6421681d7c64082f910bf9cb03c99d4006a2cd883d51d54f11a18f90188f141a78b9d69a9a031c284a14f8f1

diff --git a/dev-python/openapi-core/metadata.xml b/dev-python/openapi-core/metadata.xml
new file mode 100644
index 000000000000..13f408253cd2
--- /dev/null
+++ b/dev-python/openapi-core/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">p1c2u/openapi-core</remote-id>
+		<remote-id type="pypi">openapi-core</remote-id>
+	</upstream>
+	<stabilize-allarches/>
+</pkgmetadata>

diff --git a/dev-python/openapi-core/openapi-core-0.14.2.ebuild b/dev-python/openapi-core/openapi-core-0.14.2.ebuild
new file mode 100644
index 000000000000..810e7efb1133
--- /dev/null
+++ b/dev-python/openapi-core/openapi-core-0.14.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Client-side and server-side support for the OpenAPI Specification v3"
+HOMEPAGE="
+	https://github.com/p1c2u/openapi-core/
+	https://pypi.org/project/openapi-core/
+"
+SRC_URI="
+	https://github.com/p1c2u/openapi-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/isodate[${PYTHON_USEDEP}]
+	dev-python/dictpath[${PYTHON_USEDEP}]
+	dev-python/openapi-schema-validator[${PYTHON_USEDEP}]
+	dev-python/openapi-spec-validator[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+
+BDEPEND="test? (
+	dev-python/django[${PYTHON_USEDEP}]
+	dev-python/djangorestframework[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/responses[${PYTHON_USEDEP}]
+	dev-python/webob[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# falcon not packaged
+	rm -r tests/integration/contrib/falcon || die
+
+	# Theses tests fail to collect
+	rm tests/integration/validation/test_security_override.py || die
+	rm tests/integration/validation/test_read_only_write_only.py || die
+
+	# There's a problem in the test suite here
+	rm tests/unit/unmarshalling/test_unmarshal.py || die
+	rm tests/integration/contrib/django/test_django_rest_framework_apiview.py || die
+
+	sed -i -e '/--cov/d' setup.cfg || die
+	distutils-r1_src_prepare
+}