[gentoo-commits] proj/kde:master commit in: kde-frameworks/breeze-icons-rcc/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     35a2a5d95ae352bd9f17a837e772031bdc76c772
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 10 07:26:48 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jun 10 07:32:11 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=35a2a5d9

kde-frameworks/breeze-icons-rcc: 5.95.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../breeze-icons-rcc-5.95.0.ebuild                 | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.95.0.ebuild b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.95.0.ebuild
new file mode 100644
index 0000000000..41c19ea3eb
--- /dev/null
+++ b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.95.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="breeze-icons"
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake kde.org python-any-r1
+
+DESCRIPTION="Breeze SVG icon theme binary resource"
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+DEPEND="test? ( dev-qt/qttest:5 )"
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON
+		-DSKIP_INSTALL_ICONS=ON
+	)
+	cmake_src_configure
+}