[gentoo-commits] repo/gentoo:master commit in: dev-python/trio/

["Michał Górny" <mgorny@gentoo.org>]

commit:     f676c1f1cdb05d864b4c7b7df61defbfe2ae53f4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  8 04:39:23 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun  8 05:34:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f676c1f1

dev-python/trio: Bump to 0.21.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/trio/Manifest           |  1 +
 dev-python/trio/trio-0.21.0.ebuild | 66 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index b15fbda9fd41..061047fccaa6 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
 DIST trio-0.20.0.tar.gz 491254 BLAKE2B 354e8019d1ba8ac35bbb00477806ab87d62de0e9a94b1ff3a4d63c024af8cd40261c46a2c9449f38550e809938f3c6ee620a47e866bc31203c3c4a4984446fa5 SHA512 9aa431d0bc28737dd48a7358446acaffbf34860dc467ac121166f7241ebf4a4ed8bcdc8dc0277034e3c3fd70f1f8a57d790e98bdda7a1141f2c53c6b85a97a3c
+DIST trio-0.21.0.gh.tar.gz 491228 BLAKE2B e5f65d3aa9e4bc0c449e3986048d63fe3001a2eee96dbe5d8c088e0fce786b1d50861b47170baa7cced097938b16c92f0efd51518404a5e0ea6a17a48d656823 SHA512 383b11f264ddf4c78eb75829472826ebacf32d063790e8d4681d5df2f21c4f9287884db1752fd19976b674643adf7299816d4404e3032193ef90f522ad9cfa79

diff --git a/dev-python/trio/trio-0.21.0.ebuild b/dev-python/trio/trio-0.21.0.ebuild
new file mode 100644
index 000000000000..6fc1ee37808f
--- /dev/null
+++ b/dev-python/trio/trio-0.21.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+# NB: we're ignoring tests that require trustme+pyopenssl
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/immutables \
+	dev-python/sphinxcontrib-trio \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these tests require internet access
+		trio/tests/test_ssl.py
+		trio/tests/test_highlevel_ssl_helpers.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+
+		# incompatible ipython version?
+		trio/_core/tests/test_multierror.py::test_ipython_exc_handler
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m "not redistributors_should_skip"
+}