[gentoo-commits] repo/gentoo:master commit in: dev-python/twine/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c60544c82e7aa3050813320f11b0755a713c3211
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  2 06:24:31 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun  2 06:42:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c60544c8

dev-python/twine: Bump to 4.0.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/twine/Manifest           |  1 +
 dev-python/twine/twine-4.0.1.ebuild | 80 +++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index 42e5f0db5926..af094fb015a9 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-4.0.0.tar.gz 214420 BLAKE2B 0a1dc91ed9308252d5db3825c8b642e015720bfe7a95dd9a92ba347cbf1eedede85b18b9c310fe20322928db8e44f988bffb3845748ce9817ecbd5b521fb25c8 SHA512 c97a4315bd2a923979aa3a6cebf826ef022a9e510383f7f1debf941b6eedc47642c999702bdc3377a9740f381ed4dc442a542f02a44e521040cb67fb342e9b7e
+DIST twine-4.0.1.gh.tar.gz 214569 BLAKE2B 82c1793718cfd7d81d9745d16dfe21f59fdfd8b157840ff29629f8b7b86c1e36281f1ed9ba613ec0048c8eef8a2c80d2b9b160893ed953b06c9bfb027f5299e0 SHA512 0b5d24c56731239400b6713e0e52d1cfdb399a84e886b02ea4b59e7af69cc1578e03bf442cca4b2ea5f400995955d27c8d9d3cc17a6ea59013bdaaf6ac63a567

diff --git a/dev-python/twine/twine-4.0.1.ebuild b/dev-python/twine/twine-4.0.1.ebuild
new file mode 100644
index 000000000000..7f4803fc0f57
--- /dev/null
+++ b/dev-python/twine/twine-4.0.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/importlib_metadata-3.6[${PYTHON_USEDEP}]
+	>=dev-python/keyring-15.1[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/readme_renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.0.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+	sed -i -e '/--cov/d' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# regression due to deps?
+		tests/test_check.py::test_fails_rst_no_content
+	)
+	[[ ${EPYTHON} == python3.11 ]] && EPYTEST_DESELECT+=(
+		# confused by extra log entries that don't seem relevant
+		tests/test_auth.py::test_warns_for_empty_password
+	)
+
+	local -x COLUMNS=80
+	epytest
+}