[gentoo-commits] repo/gentoo:master commit in: dev-python/eyeD3/

["Sam James" <sam@gentoo.org>]

commit:     f27b938cac7e3d14d802072a646b90c7453a2cb4
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue May 31 10:12:58 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May 31 10:14:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f27b938c

dev-python/eyeD3: add Python 3.11

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/eyeD3/eyeD3-0.9.6-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/eyeD3/eyeD3-0.9.6-r1.ebuild b/dev-python/eyeD3/eyeD3-0.9.6-r1.ebuild
new file mode 100644
index 000000000000..a29cbbbf2096
--- /dev/null
+++ b/dev-python/eyeD3/eyeD3-0.9.6-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Module for manipulating ID3 (v1 + v2) tags in Python"
+HOMEPAGE="https://eyed3.nicfit.net/"
+SRC_URI="https://github.com/nicfit/eyeD3/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? ( https://eyed3.nicfit.net/releases/eyeD3-test-data.tgz )"
+
+LICENSE="GPL-2"
+SLOT="0.7"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	dev-python/filetype[${PYTHON_USEDEP}]
+	|| (
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+# note: most of the deps are optional runtime deps / plugin deps
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pylast[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# requires unpackaged factory-boy, doesn't seem to relevant
+	# to anything but eyeD3 usage with factory-boy
+	rm tests/test_factory.py || die
+	# requires unpackaged grako
+	rm tests/test_display_plugin.py || die
+
+	if use test; then
+		mv "${WORKDIR}"/eyeD3-test-data tests/data || die
+	fi
+
+	distutils-r1_src_prepare
+}