[gentoo-commits] repo/gentoo:master commit in: net-misc/freerdp/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     197e552bb1ca8b1a9293fce62e94dcc65e7661ad
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Mon May  2 21:24:01 2022 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Mon May  2 21:24:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=197e552b

net-misc/freerdp: add 2.7.0

Bug: https://bugs.gentoo.org/842231
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 net-misc/freerdp/Manifest             |   1 +
 net-misc/freerdp/freerdp-2.7.0.ebuild | 124 ++++++++++++++++++++++++++++++++++
 2 files changed, 125 insertions(+)

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 33cce443e211..0717b684ad13 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -2,3 +2,4 @@ DIST freerdp-2.4.1.tar.gz 7300797 BLAKE2B cd14cadfbad9f30ab6ee6ba80c3a3bfb191b68
 DIST freerdp-2.5.0.tar.gz 7303832 BLAKE2B 93f7428f04e0f5faaf93c08acd75cb4af655b52fc89653d470f28175e8d3fad9b61c9c19bfd7fb7e6edf947c9cca12a1d6a98b410409cd9f96007de1bc52b034 SHA512 d9f70bc12175d4ab1c874a2106d37c7d8c0f5e1f81ef30329518eecc5c58c0131429243a3faa6c7d68b187c8f43f93000a1de0e39e81ab71ad626e33f373f33d
 DIST freerdp-2.5.0_p39.tar.gz 37767 BLAKE2B ae520958e2b1418c46d20c4fb50ecf952d0b0cf2c455dca2d6cf08daf85dabcf2dacb5934240a7c3411ff490903bf15a21f621267a47e81e57edaf520b93c274 SHA512 e7455953f11b82290f6689f4ebaa030e73bf5ea3dac768527027bbb09e4d925208d9b324ae175d28642c161eb0e3227f6c98f4c8717e1f83c81d4399586495db
 DIST freerdp-2.6.1.tar.gz 7270692 BLAKE2B c4da1868be5f1fc40fb14ba54b33c7c79c66cf44b464e4f2e62cfd9cad2da3a6980dc5d33fdd93a11bf8138a75e4427c46977a7110f4cb8669827c0940e3b196 SHA512 4de8718924b63b32fb5068c6538ba31f966e3cc14d17ae42dc90a01787dfff388c486263dcc085777baf4ce25b89f12191e1a5d6afb42f17cbcb38282f4868b7
+DIST freerdp-2.7.0.tar.gz 7274512 BLAKE2B 82dc1403c8c2cada81585e869315ee2601d1fe87c3cb293f3cfe90278110644a5dab42ec0b516a204a651dc3127e458cd47994269644c41183501b848e399348 SHA512 9e9df14a39412f3ee3cd8a97123377d3da39492f66a0caee37d122f487639483d172cb89824523d57516aa83d22b9da569f2169a0598b475fbe70eab65fa2dc4

diff --git a/net-misc/freerdp/freerdp-2.7.0.ebuild b/net-misc/freerdp/freerdp-2.7.0.ebuild
new file mode 100644
index 000000000000..99ddb2dd9804
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.7.0.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2011-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	openh264? ( media-libs/openh264:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=()
+	use elibc_musl && myctestargs+=( -E TestBacktrace )
+	cmake_src_test
+}