From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1391894-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits) server-digest SHA256)
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id D2040158090
for <garchives@archives.gentoo.org>; Mon, 2 May 2022 10:52:40 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 1E711E0AE1;
Mon, 2 May 2022 10:52:40 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id DB085E0AE1
for <gentoo-commits@lists.gentoo.org>; Mon, 2 May 2022 10:52:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id B1BE534156A
for <gentoo-commits@lists.gentoo.org>; Mon, 2 May 2022 10:52:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 115B9105
for <gentoo-commits@lists.gentoo.org>; Mon, 2 May 2022 10:52:37 +0000 (UTC)
From: "Ulrich Müller" <ulm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Ulrich Müller" <ulm@gentoo.org>
Message-ID: <1651488733.030998bee4664b6c5b2fd65e6cb8c077164a3f2d.ulm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-im/zoom/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-im/zoom/Manifest net-im/zoom/zoom-5.9.6.2225-r2.ebuild
X-VCS-Directories: net-im/zoom/
X-VCS-Committer: ulm
X-VCS-Committer-Name: Ulrich Müller
X-VCS-Revision: 030998bee4664b6c5b2fd65e6cb8c077164a3f2d
X-VCS-Branch: master
Date: Mon, 2 May 2022 10:52:37 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 29164195-ee42-4f87-a75a-688ba7930147
X-Archives-Hash: f9c703a71e0a100a9b2c02a621103bee
commit: 030998bee4664b6c5b2fd65e6cb8c077164a3f2d
Author: Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Mon May 2 10:52:13 2022 +0000
Commit: Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Mon May 2 10:52:13 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=030998be
net-im/zoom: Restore version 5.6.9.2225
Bug: https://bugs.gentoo.org/835930#c44
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>
net-im/zoom/Manifest | 1 +
net-im/zoom/zoom-5.9.6.2225-r2.ebuild | 171 ++++++++++++++++++++++++++++++++++
2 files changed, 172 insertions(+)
diff --git a/net-im/zoom/Manifest b/net-im/zoom/Manifest
index c40804235327..2da420e5937c 100644
--- a/net-im/zoom/Manifest
+++ b/net-im/zoom/Manifest
@@ -1 +1,2 @@
DIST zoom-5.10.4.2845_x86_64.tar.xz 129882272 BLAKE2B e1d1e4aa460e56afc906ec2a0b9f8fd3c4ef40bfcc303993b01bde8d84f9935ab867c1527922771c19df451c4452b3838bcb262fbd43bcb65c2b35c021c56c07 SHA512 60115858e391c064893cdb85362fba733c48326acc8bb46e01fd8d6b1875ec0f2b53bf9c85b64a0d33456a781a9c613208705fa4cf03d87959d5254caf00c14f
+DIST zoom-5.9.6.2225_x86_64.tar.xz 57384044 BLAKE2B a6712499d903fa715170b9a50bf3fd1fadf7f403f4c9a9ff5ed890faf65ffd5564d06f64f26ca596598ef2c5cb53b4a477d8b08f7f7d44282911a890a00900d2 SHA512 f2899377c66cada60bf08326b7cd06a64b659d06fbdc19f0d6f1f0a6458bbfa0a40e59bdfb7ab4fe4877c0bde2f29fd0bfb8e05227b3c7cca66880e713345f10
diff --git a/net-im/zoom/zoom-5.9.6.2225-r2.ebuild b/net-im/zoom/zoom-5.9.6.2225-r2.ebuild
new file mode 100644
index 000000000000..01a338330463
--- /dev/null
+++ b/net-im/zoom/zoom-5.9.6.2225-r2.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop readme.gentoo-r1 wrapper xdg-utils
+
+DESCRIPTION="Video conferencing and web conferencing service"
+HOMEPAGE="https://zoom.us/"
+SRC_URI="https://zoom.us/client/${PV}/${PN}_x86_64.tar.xz -> ${P}_x86_64.tar.xz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="bundled-libjpeg-turbo +bundled-qt opencl pulseaudio wayland"
+RESTRICT="mirror bindist strip"
+
+RDEPEND="!games-engines/zoom
+ dev-libs/glib:2
+ >=dev-libs/quazip-1.0:0=
+ media-libs/fdk-aac:0/2
+ media-libs/fontconfig
+ media-libs/freetype
+ media-sound/mpg123
+ sys-apps/dbus
+ sys-apps/util-linux
+ sys-libs/glibc
+ virtual/opengl
+ x11-libs/libX11
+ x11-libs/libxcb
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libxkbcommon[X]
+ x11-libs/libXrender
+ x11-libs/libXtst
+ x11-libs/xcb-util-image
+ x11-libs/xcb-util-keysyms
+ opencl? ( virtual/opencl )
+ pulseaudio? ( media-sound/pulseaudio )
+ !pulseaudio? ( media-libs/alsa-lib )
+ wayland? ( dev-libs/wayland )
+ !bundled-libjpeg-turbo? ( >=media-libs/libjpeg-turbo-2.0.5 )
+ !bundled-qt? (
+ dev-libs/icu
+ dev-qt/qtcore:5
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5[widgets]
+ dev-qt/qtdiag:5
+ dev-qt/qtgraphicaleffects:5
+ dev-qt/qtgui:5
+ dev-qt/qtlocation:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtquickcontrols:5[widgets]
+ dev-qt/qtquickcontrols2:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ wayland? ( dev-qt/qtwayland )
+ )"
+
+BDEPEND="dev-util/bbe
+ bundled-libjpeg-turbo? ( dev-util/patchelf )"
+
+QA_PREBUILT="opt/zoom/*"
+
+src_prepare() {
+ default
+
+ # The tarball doesn't contain an icon, so extract it from the binary
+ bbe -s -b '/<svg width="32" height="32"/:/<\x2fsvg>\n/' -e 'J 1;D' zoom \
+ >videoconference-zoom.svg && [[ -s videoconference-zoom.svg ]] \
+ || die "Extraction of icon failed"
+
+ if ! use pulseaudio; then
+ # For some strange reason, zoom cannot use any ALSA sound devices if
+ # it finds libpulse. This causes breakage if media-sound/apulse[sdk]
+ # is installed. So, force zoom to ignore libpulse.
+ bbe -e 's/libpulse.so/IgNoRePuLsE/' zoom >zoom.tmp || die
+ mv zoom.tmp zoom || die
+ fi
+
+ if use bundled-libjpeg-turbo; then
+ # Remove insecure RPATH from bundled lib
+ patchelf --remove-rpath libturbojpeg.so || die
+ fi
+}
+
+src_install() {
+ insinto /opt/zoom
+ exeinto /opt/zoom
+ doins -r json ringtone sip timezones translations
+ doins *.pcm Embedded.properties version.txt
+ doexe zoom zopen ZoomLauncher *.sh
+ dosym -r {"/usr/$(get_libdir)",/opt/zoom}/libmpg123.so
+ dosym -r "/usr/$(get_libdir)/libfdk-aac.so.2" /opt/zoom/libfdkaac2.so
+ dosym -r "/usr/$(get_libdir)/libquazip1-qt5.so" /opt/zoom/libquazip.so
+
+ if use opencl; then
+ doexe aomhost libaomagent.so libclDNN64.so libmkldnn.so
+ dosym -r {"/usr/$(get_libdir)",/opt/zoom}/libOpenCL.so.1
+ fi
+
+ if use bundled-libjpeg-turbo; then
+ doexe libturbojpeg.so
+ else
+ dosym -r {"/usr/$(get_libdir)",/opt/zoom}/libturbojpeg.so
+ fi
+
+ if use bundled-qt; then
+ doexe libicu*.so.56 libQt5*.so.5
+ doins qt.conf
+
+ local dirs="Qt* bearer generic iconengines imageformats \
+ platforminputcontexts platforms wayland* xcbglintegrations"
+ doins -r ${dirs}
+ find ${dirs} -type f '(' -name '*.so' -o -name '*.so.*' ')' \
+ -printf '/opt/zoom/%p\0' | xargs -0 -r fperms 0755 || die
+
+ ( # Remove libs and plugins with unresolved soname dependencies
+ cd "${ED}"/opt/zoom || die
+ rm -r Qt/labs/location QtQml/RemoteObjects \
+ QtQuick/LocalStorage QtQuick/Particles.2 QtQuick/Scene2D \
+ QtQuick/Scene3D QtQuick/XmlListModel \
+ platforms/libqeglfs.so platforms/libqlinuxfb.so || die
+ use wayland || rm -r libQt5Wayland*.so* QtWayland wayland* \
+ platforms/libqwayland*.so || die
+ )
+ else
+ local qtzoom="5.12" qtver=$(best_version dev-qt/qtcore:5)
+ if [[ ${qtver} != dev-qt/qtcore-${qtzoom}.* ]]; then
+ ewarn "You have disabled the bundled-qt USE flag."
+ ewarn "You may experience problems when running Zoom with"
+ ewarn "a version of the system-wide Qt libs other than ${qtzoom}."
+ ewarn "See https://bugs.gentoo.org/798681 for details."
+ fi
+ fi
+
+ make_wrapper zoom /opt/zoom{/zoom,,}
+ make_desktop_entry "zoom %U" Zoom videoconference-zoom \
+ "Network;VideoConference;" \
+ "MimeType=$(printf '%s;' \
+ x-scheme-handler/zoommtg \
+ x-scheme-handler/zoomus \
+ application/x-zoom)"
+ doicon videoconference-zoom.svg
+ doicon -s scalable videoconference-zoom.svg
+
+ local DOC_CONTENTS="Some of Zoom's screen share features (e.g.
+ the whiteboard) require display compositing. If you encounter
+ a black window when sharing the screen, then one of the following
+ actions should help:
+ \\n- Enable compositing in your window manager if it is supported
+ \\n- Alternatively, run the xcompmgr command (from x11-misc/xcompmgr)"
+ use wayland \
+ && DOC_CONTENTS+="\\n\\nTo enable screen sharing on GNOME Wayland,
+ edit ~/.config/zoomus.conf and change the value of
+ enableWaylandShare to true."
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}