[gentoo-commits] repo/gentoo:master commit in: media-sound/cava/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     18138630e12b7b52c8b45daab33166b86e5d946b
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 24 19:46:47 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sun Apr 24 21:33:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18138630

media-sound/cava: add 0.8.2

This version removes the need for xxd/vim-core. Also no
longer segfault if no audio backends, so remove the warning.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-sound/cava/Manifest          |  1 +
 media-sound/cava/cava-0.8.2.ebuild | 64 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/media-sound/cava/Manifest b/media-sound/cava/Manifest
index 47f15504e9aa..7a932b4766f8 100644
--- a/media-sound/cava/Manifest
+++ b/media-sound/cava/Manifest
@@ -1 +1,2 @@
 DIST cava-0.8.1.tar.gz 99310 BLAKE2B e7d85a6241fee0a4e45f5c50d068b2300ee2d41a019738dc87317986525571eca5f56831e937580fecf949cc85e11512340678b5842ee6f2f3a99f9d06812c3a SHA512 fad4e4fefe98300cc2774a168322056e4181cd2a0cc77a8622471d86512bab9eea6c09559a75518785fbcafee5a958e6d95c8fe5ce1816253e4dec99a23fae1c
+DIST cava-0.8.2.tar.gz 103930 BLAKE2B feeb8313bd9b74029d101acaecfeed02e449cc29dceb2c119d7deef65befae418526274e6bad14dc0df7eaed90850ecae4a4064a414d94950ab3c24943281017 SHA512 8ab146987324fad97dea5e9fd893de6c12b00cbb074d835c1e334d75c0d32cb4cbbc13cf72f7899191ebd5d346505b2639dcad5312e5ab00975b29a006ba41b3

diff --git a/media-sound/cava/cava-0.8.2.ebuild b/media-sound/cava/cava-0.8.2.ebuild
new file mode 100644
index 000000000000..7afa4ce04e09
--- /dev/null
+++ b/media-sound/cava/cava-0.8.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Console-based Audio Visualizer for Alsa"
+HOMEPAGE="https://github.com/karlstav/cava/"
+SRC_URI="https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa +ncurses portaudio pulseaudio sdl sndio"
+
+RDEPEND="
+	dev-libs/iniparser:4
+	sci-libs/fftw:=
+	alsa? ( media-libs/alsa-lib )
+	ncurses? ( sys-libs/ncurses:= )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl2[opengl,video] )
+	sndio? ( media-sound/sndio:= )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
+)
+
+src_prepare() {
+	default
+
+	# https://github.com/karlstav/cava/issues/450
+	sed -i 's/-Werror //' Makefile.am || die
+
+	echo ${PV} > version || die
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable alsa input-alsa)
+		$(use_enable portaudio input-portaudio)
+		$(use_enable pulseaudio input-pulse)
+		$(use_enable sndio input-sndio)
+
+		$(use_enable ncurses output-ncurses)
+		$(use_enable sdl output-sdl)
+
+		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
+	)
+
+	econf "${econfargs[@]}"
+}
+
+pkg_postinst() {
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog "A default ~/.config/cava/config will be created after initial"
+		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
+		elog "for configuring audio input and more."
+	fi
+}