[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     6bb4e4fe4a65504b4316cd70e05365e1fc78c842
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 22 20:13:58 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Apr 22 20:13:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6bb4e4fe

app-emulation/86Box: add 3.4.1

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.4.1.ebuild | 68 ++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest           |  1 +
 2 files changed, 69 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.4.1.ebuild b/app-emulation/86Box/86Box-3.4.1.ebuild
new file mode 100644
index 000000000000..9463759e394c
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.4.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index ad63835eb66f..eaf6604969dd 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
+DIST 86Box-3.4.1.tar.gz 4221251 BLAKE2B 20e3dfbab2a624a834766e4b7767fade045358ef394d3178d02b909e1e696b723e89618bf97e0636bfff882353ae77be23fccc4367513f95fc2e4a08c22d53c5 SHA512 76a4f8d129bdad6d4eef5d34c68b4a90840b00ba0bc2771d07a24ffcf7baa8db6ce2a23936675e0126a2938f48486a734bcebae7f2df2bbaf67ffa7e8dc3b5fa
 DIST 86Box-3.4.tar.gz 4218439 BLAKE2B ea5dbc31ca3b801f45c9923d0723fcf7f71dfda2a3835b54ee9c700650f28dbb8ed8644b0344c7cfea244fd755847842466bf203482b5eabde85f72b60b15fd8 SHA512 a60034e027bd188343c8eaefe6c56699bf5f7b8016cb1443b081655377bddbd84159cd63362d268a73fc6a5f92ec38544d2fb82aacdb40e8d0eec83bba00cff0