[gentoo-commits] repo/gentoo:master commit in: media-libs/libzen/

["Sam James" <sam@gentoo.org>]

commit:     bcddbfec2336c7df227057df1e86a6c3806aa684
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 22 01:02:52 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Apr 22 01:03:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bcddbfec

media-libs/libzen: add 0.4.39

Closes: https://bugs.gentoo.org/831208
Bug: https://bugs.gentoo.org/836564
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/libzen/Manifest             |  1 +
 media-libs/libzen/libzen-0.4.39.ebuild | 67 ++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-libs/libzen/Manifest b/media-libs/libzen/Manifest
index 44474f91c74c..5bf6113ba4ba 100644
--- a/media-libs/libzen/Manifest
+++ b/media-libs/libzen/Manifest
@@ -1 +1,2 @@
 DIST libzen_0.4.38.tar.bz2 129706 BLAKE2B 3e40e31663f655885f47b7674936a765cce032da25fcc3f57604b116414bf4348db363a4745bf98126879de9d2de5d4443af1fe3a1f64a7bafd3525eb1ca38da SHA512 d946cd2349848925e13a3fb6aab5ad4f5aca28bc89b3263faca3096d7bbcae3a4ff9ed2552bf005b4ca1f4c8c8f59856f4c4aafa7c734ecebd078e6fc40a9a0b
+DIST libzen_0.4.39.tar.bz2 129816 BLAKE2B ff3ffe1b53234e567be12e86deb5dddd54584c112d297bd50764a980f4a3bcd51a08af630d482cca3157fcc9b8452f644807d6055d88420dcc6c311725ed402d SHA512 f261a676cbde9a877b85df536306a035ede1acdc5d827049698d19b3ecd8a65e5f6cfe66851fda034e1b31c95f6d6e82b78b0bc35989ec1568a010fb88a5a2d8

diff --git a/media-libs/libzen/libzen-0.4.39.ebuild b/media-libs/libzen/libzen-0.4.39.ebuild
new file mode 100644
index 000000000000..f4c444cbce43
--- /dev/null
+++ b/media-libs/libzen/libzen-0.4.39.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_PN="ZenLib"
+DESCRIPTION="Shared library for libmediainfo and mediainfo"
+HOMEPAGE="https://github.com/MediaArea/ZenLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.bz2"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_PN}/Project/GNU/Library
+
+src_prepare() {
+	default
+
+	sed -i 's:-O2::' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-unicode \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd "${WORKDIR}"/${MY_PN}/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	# remove since the pkgconfig file should be used instead
+	rm "${D}"/usr/bin/libzen-config
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Format/Html Format/Http HTTP_Client ; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
+	done
+
+	dodoc "${WORKDIR}"/${MY_PN}/History.txt
+	if use doc ; then
+		docinto html
+		dodoc "${WORKDIR}"/${MY_PN}/Doc/*
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}