From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1384674-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2516715808B
for <garchives@archives.gentoo.org>; Mon, 11 Apr 2022 16:07:35 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 9A16BE09FE;
Mon, 11 Apr 2022 16:07:30 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 0D817E09FE
for <gentoo-commits@lists.gentoo.org>; Mon, 11 Apr 2022 16:07:30 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 3D7303419E4
for <gentoo-commits@lists.gentoo.org>; Mon, 11 Apr 2022 16:07:28 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 7E4353AB
for <gentoo-commits@lists.gentoo.org>; Mon, 11 Apr 2022 16:07:25 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1649693241.1d528dcd9a315a774967e1aa57a8ad2f22a92318.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/django/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/django/Manifest dev-python/django/django-3.2.13.ebuild
X-VCS-Directories: dev-python/django/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 1d528dcd9a315a774967e1aa57a8ad2f22a92318
X-VCS-Branch: master
Date: Mon, 11 Apr 2022 16:07:25 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: caec1ca4-5062-4845-a855-a0af32c2a72f
X-Archives-Hash: 5f441b3194cc660109ead3962f398c8e
commit: 1d528dcd9a315a774967e1aa57a8ad2f22a92318
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 15:20:02 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 16:07:21 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d528dcd
dev-python/django: Bump to 3.2.13
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-3.2.13.ebuild | 109 +++++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 9355185ec9b8..3c107a799cef 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,8 @@ DIST Django-2.2.27.checksum.txt 2556 BLAKE2B 770dc5670d0d4aebcfd1956d644b9d7e4e5
DIST Django-2.2.27.tar.gz 9185716 BLAKE2B 26d509c722c62b5bf784331466a97ad1b961715572da9e6add4be1bdc7cf999c0ec7c763d9bc8ab2fc1ca35a48783feaf748c3c9388ae9f5f3e393972deea734 SHA512 0db670651a820b49d855e38a336c0c6990ce4701bb686c5e8a292ccb03342e995c61c2c628b1d625d2715404e969fc31c256e5bf0fd6c1ff714d1c1c1ee30bff
DIST Django-3.2.12.checksum.txt 2556 BLAKE2B 7ae6e41305b5b07969ddad3474a0819359dff888fc3bdc1c5000ded1b9b726a7c55aa7aaffc85184558edcc6c12b617c8270cc569fa8e645622206631979a9c2 SHA512 5098dde440a15ad066fa7927943f4ec66bb925798afcb42101c5cf50b8148301866c39ad37ebb5db9d7f9e195953337c03dc6fa2c49758716f969ee2ce414d24
DIST Django-3.2.12.tar.gz 9812448 BLAKE2B 39b6e7e8f50b79d7be62be171eb358ab815c9dd630b8b2ad2cf085c42c79a6a8c92914fae3c471f41578e65fa09f011f959dd0794c804e7b30cfbc9411cf4f4b SHA512 fc8ad3af019b268d514cc5240cac9c6b2fbf3a169c7933e8ab2da92e9cfed72df7a2784a8d92eaec8105bc9c245763acd307178bdf662e5d51407e72ae9d8683
+DIST Django-3.2.13.checksum.txt 2554 BLAKE2B 301d816685f6d97c4a18b4f9d015b063521a7e90a870f1c95ec37ebbc1d4e7311abfee7f7c4aafaa40932334d0eab68fc768dcf21acfffe1d098cabd71ea161a SHA512 ef4a5d0fb8e885cbc2854a4b9b2380dec1cec0e8f6d9bc54179354eb6170755bd6f02268ad5bdc81fdea9d30022422462b0b14894ccc0f37d2e7288aeda83abb
+DIST Django-3.2.13.tar.gz 9813985 BLAKE2B eb8319cc225491fc71f719d2eef6daa05114a97b1302093a0cf0f77bb2a51f398e7a034df7aa52c6a64e9796b9cc66b127fccee810cb38508506ba4cd121cfbf SHA512 08f056b18bc04b95d6705cf70c2ecc5be0c1324e0b38582991b907ed5977c4e3d35417ccf4ec06c2436a718e3aae007b015f0d40dd94ce5cfb129a54cceb6578
DIST Django-4.0.2.checksum.txt 2547 BLAKE2B 532139126846e1758bbe7b4dc4ad4aad6c6b3607e298f4373366239637ceca7d01a26472b2a87917e64db7140d28a76c1f5fbb396e7022b1a42b723551770d1f SHA512 eddd8ac31fc60f803f1e6f975c079e84e5ef997e8ac93b7dcf3573bd0c5d057adeb6f092acaecb200529044d81aa2db9849c1c13525678c8c2bd27bd14d6b280
DIST Django-4.0.2.tar.gz 9996300 BLAKE2B 422b0bb000e7f62a854dc8fa686001acc3f629ded462d2520fad9486a9c8eb5d501d29c6a9f30f63ff8da128ded6f40281439371eb688fb9bc95f2377c5ca0f7 SHA512 c64b25aa69b826805cc7a3efcd63ae41bbc31a61e68cdbda90e6bcec6bd8e2c5fc47b82176d0c1708f55d2c7b082c71939b89cb0621fcf1929d1475e3d393a97
DIST Django-4.0.3.checksum.txt 2550 BLAKE2B 19471819fb593611217ae13a7dcb6bc67a0323daa94f4a4aeee508305aa09edbbd88ea759968ac989a1971bd72df766c7651e969aa86d3cbddd65b2bb3bf7efa SHA512 573cd0b9291698bf3218d6a77c146b5cda814e99c01cc2c455bf1b5ab2c4cbf4f2f569ea14a108e658237e933a69ec1a5288c293174916f4393ecb119231b9dc
diff --git a/dev-python/django/django-3.2.13.ebuild b/dev-python/django/django-3.2.13.ebuild
new file mode 100644
index 000000000000..3065555963a8
--- /dev/null
+++ b/dev-python/django/django-3.2.13.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ !!<dev-python/ipython-7.21.0-r1
+ !!=dev-python/ipython-7.22.0-r0
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_prepare_all() {
+ # Fails because of warnings
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die
+ # TODO: this suddenly started failing
+ sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+ optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}