[gentoo-commits] repo/gentoo:master commit in: app-misc/datovka/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     2bc77592d4af6cefc036bb001140114be5cc8543
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Apr  5 20:04:05 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Apr  5 20:06:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2bc77592

app-misc/datovka: Use qt5_get_bindir to find lrelease not in PATH

EAPI-8 bump, fix BDEPEND.

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-misc/datovka/datovka-4.18.0-r1.ebuild | 56 +++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/app-misc/datovka/datovka-4.18.0-r1.ebuild b/app-misc/datovka/datovka-4.18.0-r1.ebuild
new file mode 100644
index 000000000000..f12fa66b0f55
--- /dev/null
+++ b/app-misc/datovka/datovka-4.18.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="GUI to access the Czech data box e-government system"
+HOMEPAGE="https://www.datovka.cz/"
+SRC_URI="https://secure.nic.cz/files/datove_schranky/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# minimum Qt version required
+QT_PV="5.14.0:5"
+
+RDEPEND="
+	>=dev-libs/openssl-1.0.2:0=
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtgui-${QT_PV}
+	>=dev-qt/qtnetwork-${QT_PV}
+	>=dev-qt/qtprintsupport-${QT_PV}
+	>=dev-qt/qtsql-${QT_PV}[sqlite]
+	>=dev-qt/qtsvg-${QT_PV}
+	>=dev-qt/qtwidgets-${QT_PV}
+	>=net-libs/libisds-0.11
+	>=app-misc/libdatovka-0.2.0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-qt/linguist-tools-${QT_PV}
+	virtual/pkgconfig
+"
+
+DOCS=( ChangeLog README )
+
+src_configure() {
+	$(qt5_get_bindir)/lrelease datovka.pro || die
+	eqmake5 PREFIX="/usr" DISABLE_VERSION_NOTIFICATION=1 TEXT_FILES_INST_DIR="/usr/share/${PN}/"
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}