[gentoo-commits] repo/gentoo:master commit in: dev-ruby/coderay/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     d2d788d1168524be174b6fc463442d4c4569617d
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 30 06:43:20 2022 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Thu Mar 31 05:39:22 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2d788d1

dev-ruby/coderay: update EAPI 7 -> 8

Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/coderay/coderay-1.1.3-r2.ebuild | 46 ++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-ruby/coderay/coderay-1.1.3-r2.ebuild b/dev-ruby/coderay/coderay-1.1.3-r2.ebuild
new file mode 100644
index 000000000000..e02963145021
--- /dev/null
+++ b/dev-ruby/coderay/coderay-1.1.3-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30 ruby31"
+
+# The test target also contains test:exe but that requires
+# shoulda-context which we do not have packaged yet.
+RUBY_FAKEGEM_TASK_TEST="spec test:functional test:units"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="Changes-pre-1.0.textile Changes.textile FOLDERS README_INDEX.rdoc README.markdown"
+
+RUBY_FAKEGEM_GEMSPEC="coderay.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Ruby library for syntax highlighting"
+HOMEPAGE="http://coderay.rubychan.de/"
+SRC_URI="https://github.com/rubychan/coderay/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+PATCHES=("${FILESDIR}/${P}-ruby30.patch")
+
+# Redcloth is an optional but automagically tested dependency. This
+# requires redcloth-4.2.2. We don't depend on this version to make
+# bootstrapping rspec with new versions easier, since redcloth depends
+# on rake-compiler.
+
+ruby_add_bdepend "test? ( dev-ruby/rspec:3 )"
+
+all_ruby_prepare() {
+	sed -i -e "/[Bb]undler/d" Rakefile || die
+	sed -i -e '/git ls-files/ s:^:#:' -e 's/.rc.*"/"/' coderay.gemspec || die
+	sed -i -e '/simplecov/ s:^:#:' spec/spec_helper.rb test/*/*.rb || die
+
+	# Fix failing tests for lazy evaluation in ruby26
+	sed -i -e 's/\.filter$/.filter.to_a/' test/unit/filter.rb || die
+}