[gentoo-commits] repo/gentoo:master commit in: games-board/gnome-chess/

["Matt Turner" <mattst88@gentoo.org>]

commit:     bf0d378bb6ae81322ac1ba347a128f8945c6cf63
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 25 22:01:59 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar 25 22:01:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf0d378b

games-board/gnome-chess: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 games-board/gnome-chess/Manifest                |  1 +
 games-board/gnome-chess/gnome-chess-42.0.ebuild | 58 +++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/games-board/gnome-chess/Manifest b/games-board/gnome-chess/Manifest
index 08452cb08401..131c0c7db989 100644
--- a/games-board/gnome-chess/Manifest
+++ b/games-board/gnome-chess/Manifest
@@ -1 +1,2 @@
 DIST gnome-chess-41.1.tar.xz 615936 BLAKE2B 40a6f576fadd74777599192d7493f3a16abac45fc1a29c9a4e5cf1ec4d432e18910381bb26f9700b4585e1e395601d0b6a72b316139cfe74ecb6e33c9c4f001d SHA512 71d9b51599699c24d505eb4f120d99509c5e69c00d6aba1768029f9adf8ba70be6e40d001928f141a92852fb318d9f9b2ecb01b6bcbfecaf1408b89792b25224
+DIST gnome-chess-42.0.tar.xz 661180 BLAKE2B e9fe75df1b298aad17b8b199949cb02eeea5116fa15adfedfac6ed067123ff73aad8ebb33e512f1eef97237232275528da6454de27c335a897e5e3b942a335bf SHA512 08af368b6fd032976c124a8fa8402494e73b004591eae331523a377acf72d98b9827ed189db1c1287f758f41614e878062bd1ab0b8323bf76d19b9cdedacf9a6

diff --git a/games-board/gnome-chess/gnome-chess-42.0.ebuild b/games-board/gnome-chess/gnome-chess-42.0.ebuild
new file mode 100644
index 000000000000..8dbb32678806
--- /dev/null
+++ b/games-board/gnome-chess/gnome-chess-42.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_MIN_API_VERSION="0.52"
+
+inherit gnome.org gnome2-utils meson python-any-r1 readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Play the classic two-player boardgame of chess"
+HOMEPAGE="https://wiki.gnome.org/Apps/Chess"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.0.0:1
+	>=gnome-base/librsvg-2.46.0:2
+"
+DEPEND="${RDEPEND}
+	gnome-base/librsvg:2[vala]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-util/itstool
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS="To be able to play against a computer you will need
+to install a chess engine package, for example games-board/gnuchess"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}