[gentoo-commits] repo/gentoo:master commit in: net-libs/libnma/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d0679606260857cb08593af651ab3be2c28bfd95
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 25 20:15:47 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar 25 20:53:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d0679606

net-libs/libnma: Version bump to 1.8.36

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-libs/libnma/Manifest             |  1 +
 net-libs/libnma/libnma-1.8.36.ebuild | 71 ++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/net-libs/libnma/Manifest b/net-libs/libnma/Manifest
index 91947a92f40c..ac3d86f692ba 100644
--- a/net-libs/libnma/Manifest
+++ b/net-libs/libnma/Manifest
@@ -1 +1,2 @@
 DIST libnma-1.8.34.tar.xz 1342040 BLAKE2B e81004cf97832bdd010869fd7a801ceda42b96a70a0bd0aa50f821f7e3c361716f8075ec8ae82a224b6f617ee9b3f177239a53dd9eb982dd49da409d97671fd9 SHA512 aca1e24a852072e65d1fba910613981373bb7bb7869b2e44abc9e41c527d234273f034215d62889a265aa3327ad2cce0cea7368b025df97dab12bff098310aaf
+DIST libnma-1.8.36.tar.xz 1368748 BLAKE2B b60f3d383e5a55a766be8f8df71eb710d68b388c5ec0b946789856504327f6a8093943cc7b58dba992883099a899f3f55c70e5275d495610e79cef8e3e97d1b8 SHA512 c3f675d773d1be9006c01c3149751c8da1d5d08467be6d9aa921da3d867fdc9e8b26c7e6c9bd46a6cfd38a7eb721f8bcc209b43d9789a0b55c6029e11ca0fd22

diff --git a/net-libs/libnma/libnma-1.8.36.ebuild b/net-libs/libnma/libnma-1.8.36.ebuild
new file mode 100644
index 000000000000..024459425f6e
--- /dev/null
+++ b/net-libs/libnma/libnma-1.8.36.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg vala
+
+DESCRIPTION="NetworkManager GUI library"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# pkcs11 default enabled as it's a small dep often already present by libnma users, and it was default enabled as IUSE=+gcr in nm-applet before
+IUSE="gtk-doc +introspection +pkcs11 vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+DEPEND="
+	>=gui-libs/gtk-4.0:4
+	app-text/iso-codes
+	net-misc/mobile-broadband-provider-info
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.12:3[introspection?]
+	>=net-misc/networkmanager-1.7[introspection?]
+	pkcs11? ( >=app-crypt/gcr-3.14:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+"
+RDEPEND="${DEPEND}
+	!<gnome-extra/nm-applet-1.16.0" # gschema moved to here before nm-applet-1.16.0
+BDEPEND="
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend)
+		net-misc/networkmanager[vala]
+	)
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dlibnma_gtk4=true
+		$(meson_use pkcs11 gcr)
+		-Dmore_asserts=0
+		-Dgcr_gtk4=false
+		-Diso_codes=true
+		-Dmobile_broadband_provider_info=true
+		-Dld_gc=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}