[gentoo-commits] repo/gentoo:master commit in: gui-libs/gtksourceview/

["Matt Turner" <mattst88@gentoo.org>]

commit:     e18e5899ecb9ea5bb6849f275633e4f1b6e91eb0
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 22 05:55:54 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Mar 22 06:14:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e18e5899

gui-libs/gtksourceview: Version bump to 5.4.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gui-libs/gtksourceview/Manifest                   |  1 +
 gui-libs/gtksourceview/gtksourceview-5.4.0.ebuild | 74 +++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index d92adeed13f9..afd76a45eb9a 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1 +1,2 @@
 DIST gtksourceview-5.3.2.tar.xz 1255296 BLAKE2B 03f11cf0dde09266a441f5c6d66381b4eba0f2f0197a156a7e21a7a0d08f5a179cf3d6c42cf01f56c56785986fa18966f02820274b5c010e1f604baefb6cab86 SHA512 b64e0af95aff17bbee814fd7e8738d7e4cba9bc53ceb17243ad5fde01efd39a106377b5ae00ff7fdcf61cfc087d24dd9b222eb7cc48aba8485eb6f96e30c8563
+DIST gtksourceview-5.4.0.tar.xz 1259684 BLAKE2B 1561984d967dc6ab06e02d0da6b0a90573f5bc40670cbc189cef0b56ce7be9f84b0a82ccc2cd73ff3e2fb35218785e183a83a0ad5dd5ba85b023ac221820b88c SHA512 0a84e2012639aa29613896e36bb8e73656661dbd9c045507cae3c0d9863dc1ed0390432091d2d2e62fd4a9a0f1853820a2edb406ef2deecd0996b202c7b741c3

diff --git a/gui-libs/gtksourceview/gtksourceview-5.4.0.ebuild b/gui-libs/gtksourceview/gtksourceview-5.4.0.ebuild
new file mode 100644
index 000000000000..aac7dceca54e
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.4.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-libs/glib-2.70:2
+	>=gui-libs/gtk-4.5:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}