[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdazzle/

["Matt Turner" <mattst88@gentoo.org>]

commit:     ffc4d298f2b2be662534c7a6ece2709a5aeef6e1
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 22 01:49:18 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Mar 22 02:46:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ffc4d298

dev-libs/libdazzle: Version bump to 3.44.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libdazzle/Manifest                |  1 +
 dev-libs/libdazzle/libdazzle-3.44.0.ebuild | 61 ++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-libs/libdazzle/Manifest b/dev-libs/libdazzle/Manifest
index c8061fa182d8..6d92c82b8f6d 100644
--- a/dev-libs/libdazzle/Manifest
+++ b/dev-libs/libdazzle/Manifest
@@ -1 +1,2 @@
 DIST libdazzle-3.42.0.tar.xz 450636 BLAKE2B 0a77a9ceeca2af8a001b75dbffa04cd385be89d9fac898e6b90111d240b409a54357d9668ca33e494dbb0ed932f16605f363aa69b92c548981be0db971b67dfe SHA512 db6ac54deba034627726747b8c15472aa2f640617473825698e23ca6527d5b69e9103dd82141e82b7dd7fa8bd57eadf054cdd300d46e1b65ced0fffcbc55a301
+DIST libdazzle-3.44.0.tar.xz 454948 BLAKE2B d42d98e820e7af18fc8c8a75f7b77b5d84f03a367925d16b35fe88fd5a74e69d2f170233dd6986ad47dfc4cdd2f9690323d1053341ecb11e324e758f63a25bba SHA512 eff3f65cbfd4f780afb4bda6137e8d4f1ee2cd0ab21288d07315415944ced1aa2d7ef89c2b7ebb373ac4c46b91d341bed063e9c7d1c21fa083514c8c3c9c518f

diff --git a/dev-libs/libdazzle/libdazzle-3.44.0.ebuild b/dev-libs/libdazzle/libdazzle-3.44.0.ebuild
new file mode 100644
index 000000000000..e2f4a4679d48
--- /dev/null
+++ b/dev-libs/libdazzle/libdazzle-3.44.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx
+
+DESCRIPTION="Experimental new features for GTK+ and GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# We keep newer glib/gtk+ deps to avoid GtkEventControllerMotion backports gettings used
+RDEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=x11-libs/gtk+-3.24.0:3[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
+BDEPEND="
+	>=dev-util/meson-0.49.0
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_tracing=false # extra trace debugging that would make things slower
+		-Denable_profiling=false # -pg passing
+		# On linux it'll always use a vdso based implementation that is even faster
+		# than rdtscp insn, thus never build with rdtscp until we don't support non-linux
+		# as the rdtscp using function will never get called anyways.
+		-Denable_rdtscp=false
+		-Denable_tools=true # /usr/bin/dazzle-list-counters
+		$(meson_use introspection with_introspection)
+		$(meson_use vala with_vapi)
+		$(meson_use gtk-doc enable_gtk_doc)
+		$(meson_use test enable_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}