[gentoo-commits] repo/gentoo:master commit in: media-video/amdgpu-pro-amf/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     2f61f01d231b32170e13b9ccc62115b6a5d71e7c
Author:     Adel KARA SLIMANE <adel.ks <AT> zegrapher <DOT> com>
AuthorDate: Wed Mar  9 11:43:02 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Mar 16 15:54:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f61f01d

media-video/amdgpu-pro-amf: minor version bump to 1.4.24.1384496

Signed-off-by: Adel KARA SLIMANE <adel.ks <AT> zegrapher.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-video/amdgpu-pro-amf/Manifest                |  1 +
 .../amdgpu-pro-amf-1.4.24.1384496.ebuild           | 56 ++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/media-video/amdgpu-pro-amf/Manifest b/media-video/amdgpu-pro-amf/Manifest
index 1f2a3c75799c..6c8863dd49fe 100644
--- a/media-video/amdgpu-pro-amf/Manifest
+++ b/media-video/amdgpu-pro-amf/Manifest
@@ -1 +1,2 @@
 DIST amdgpu-pro-amf-1.4.24.1376756.deb 1302168 BLAKE2B 706528317c317e0319e80decc8a9a59a0c55fed8c4c43c701ba93a2a503fbf5f2ee9fb44cfeb5bd582b013ebb8961514cb5b9faead8f24fdfe2b205f7d2dc656 SHA512 77740014e6bc2c91e822261e4fa247ac0e49747d6ff8af0c3b3046ec993c7c99621b55639ef18582021389a329e52ccc59edb85eb29d9e6a81da6986a487ec3e
+DIST amdgpu-pro-amf-1.4.24.1384496.deb 1304672 BLAKE2B a21e7d2cf9dc4fe139f87d5c61b4ac715e677fb23aa2cc3eb4a62e20776431d26e234d092d9b28ecad22de2f5acda1f21df394f3a51152c9fd36cdfddab78af2 SHA512 4620dda918196e67f99c8a1df8e3e487769bd3ad94881a3769e46a85a12648f50ba8520476c9eec9e982261354ff92f56803fd8731fa7a7e458670011426ce31

diff --git a/media-video/amdgpu-pro-amf/amdgpu-pro-amf-1.4.24.1384496.ebuild b/media-video/amdgpu-pro-amf/amdgpu-pro-amf-1.4.24.1384496.ebuild
new file mode 100644
index 000000000000..83779deedfe1
--- /dev/null
+++ b/media-video/amdgpu-pro-amf/amdgpu-pro-amf-1.4.24.1384496.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit unpacker
+
+MY_PV_HIGH=$(ver_cut 1)
+MY_PV_MIDDLE=$(ver_cut 2)
+MY_PV_LOW=$(ver_cut 3)
+MY_PV_REV=$(ver_cut 4)
+
+MY_PV="${MY_PV_HIGH}.${MY_PV_MIDDLE}.${MY_PV_LOW}"
+MY_PV_FULL="${MY_PV}-${MY_PV_REV}"
+
+MY_PN="amf-amdgpu-pro"
+
+PRO_VULKAN_PKG_VER="21.50.2"
+
+MY_LINK="https://repo.radeon.com/amdgpu/${PRO_VULKAN_PKG_VER}/ubuntu/pool/proprietary/a/${MY_PN}"
+
+DESCRIPTION="AMD's closed source Advanced Media Framework (AMF) driver"
+HOMEPAGE="https://www.amd.com/en/support"
+SRC_URI="${MY_LINK}/${MY_PN}_${MY_PV_FULL}_amd64.deb -> ${P}.deb"
+
+S="${WORKDIR}"
+
+RESTRICT="bindist mirror"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+RDEPEND="
+	media-libs/libglvnd
+	x11-libs/libX11
+"
+
+QA_PREBUILT="
+	usr/lib64/libamfrt64.so*
+"
+
+src_unpack() {
+	mkdir "${S}/${PN}-amd64" || die
+	cd "${S}/${PN}-amd64" || die
+	unpack_deb "${DISTDIR}/${P}.deb"
+}
+
+src_install() {
+	insinto "/usr/$(get_libdir)"
+
+	# AMF
+	doins "${S}/${PN}-amd64/opt/amdgpu-pro/lib/x86_64-linux-gnu/libamfrt64.so.${MY_PV}"
+	dosym "libamfrt64.so.${MY_PV}" "/usr/$(get_libdir)/libamfrt64.so"
+	dosym "libamfrt64.so.${MY_PV}" "/usr/$(get_libdir)/libamfrt64.so.1"
+}