[gentoo-commits] repo/gentoo:master commit in: media-gfx/pngquant/

["Andreas K. Hüttel" <dilfridge@gentoo.org>]

commit:     08a1c246ac9f9a1a6e4b882a2306bee7f4a56c45
Author:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  5 22:46:15 2022 +0000
Commit:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sat Mar  5 23:08:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08a1c246

media-gfx/pngquant: Version bump 2.17.0

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas K. Hüttel <dilfridge <AT> gentoo.org>

 media-gfx/pngquant/Manifest               |  1 +
 media-gfx/pngquant/pngquant-2.17.0.ebuild | 58 +++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/media-gfx/pngquant/Manifest b/media-gfx/pngquant/Manifest
index 35d6859fa55b..3cf0ca86ad69 100644
--- a/media-gfx/pngquant/Manifest
+++ b/media-gfx/pngquant/Manifest
@@ -1 +1,2 @@
 DIST pngquant-2.12.6.tar.gz 69074 BLAKE2B 3573d54d94b0085de9ffd4dd34a8fd46c49a1e02d0a6419271c17bc7ac7ab6c05d811336a3a8a8ab21d4dea774c93ee1baae141b42c255838fb1eef9cdb1a871 SHA512 8ffff346df67edf1000c71b6d26371826bc4d236b3f57ef1ec73b3b61668cff9c3ca7d541417c39bc6c89e00176c91eb28867b7a91945ac84292ca0ac54984e9
+DIST pngquant-2.17.0.tar.gz 71209 BLAKE2B 0f625b6c27bc621fd5e1d9b4c5d3cbb7eda960a7afa8e6c6813c5d74e6f48055572dfacfcc93c694dc2d3fd8a107064c2a24c0845fc5339c0289b8527056d39a SHA512 7054cb6bdc547a6e00be1ab2363e2fa5367598593359ef23a91f3af8ff210b281e10f8721bc74d86f208f45336cd61292946c17dc5f26d292998eba95978dc0b

diff --git a/media-gfx/pngquant/pngquant-2.17.0.ebuild b/media-gfx/pngquant/pngquant-2.17.0.ebuild
new file mode 100644
index 000000000000..dff2d725f4fd
--- /dev/null
+++ b/media-gfx/pngquant/pngquant-2.17.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Command-line utility and library for lossy compression of PNG images"
+HOMEPAGE="https://pngquant.org/ https://github.com/kornelski/pngquant"
+SRC_URI="https://github.com/kornelski/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 HPND rwpng"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+IUSE="cpu_flags_x86_sse2 debug lcms openmp test"
+REQUIRED_USE="test? ( lcms )"
+
+RDEPEND="
+	media-libs/libpng:0=
+	media-gfx/libimagequant:=
+	sys-libs/zlib:=
+	lcms? ( media-libs/lcms:2 )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.12.2-respect-CFLAGS.patch )
+
+src_prepare() {
+	default
+
+	# avoid silent fallback to bundled lib
+	rm -rv lib || die
+}
+
+src_configure() {
+	tc-export AR CC
+	# Hand rolled configure script, so not all flags are supported.
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--with-libimagequant \
+		$(use debug && echo --enable-debug) \
+		$(use_enable cpu_flags_x86_sse2 sse) \
+		$(use openmp && tc-has-openmp && echo --with-openmp) \
+		$(use_with lcms lcms2) \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dodoc CHANGELOG README.md
+}