[gentoo-commits] repo/gentoo:master commit in: sci-electronics/geda/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     dbf9debbe4c86a5b84f0342147d554fde250d264
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Mar  2 12:34:19 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Mar  2 12:34:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dbf9debb

sci-electronics/geda: add version 1.10.2

Closes: https://bugs.gentoo.org/701898
Bug: https://bugs.gentoo.org/824970
Bug: https://bugs.gentoo.org/643822
Bug: https://bugs.gentoo.org/681768
Bug: https://bugs.gentoo.org/717436
Bug: https://bugs.gentoo.org/779808
Bug: https://bugs.gentoo.org/704768
Bug: https://bugs.gentoo.org/642464
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 sci-electronics/geda/Manifest           |  1 +
 sci-electronics/geda/geda-1.10.2.ebuild | 89 +++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/sci-electronics/geda/Manifest b/sci-electronics/geda/Manifest
index d10e265b6bb7..4639d6ec8227 100644
--- a/sci-electronics/geda/Manifest
+++ b/sci-electronics/geda/Manifest
@@ -1 +1,2 @@
+DIST geda-gaf-1.10.2.tar.gz 14441491 BLAKE2B d6ecc4bc1390ff457396ae406fdeee909418f63d8c50e537215fa0a1131cfda91339f44ddc2c91ca0f3772f4416be1c4448fea45336c78bb601fb9b4df399b14 SHA512 c7beabf019762d9d3b4faa63f1345fb064ebbb6e0203a6c5bcab6b740d20db9f3cedf85c2f99e3ab1cb5396c06886fad1dbd5201eb7bad9e77c03511cf23b1a1
 DIST geda-gaf-1.9.2.tar.gz 10612225 BLAKE2B d09accde32f672b984bc2541404efccc886edb15e985bab287b4a619f11fc10cfd2b3ce3074d82c1a61811c4df9e515ecfbc61bd537c6943188b130062bda97f SHA512 5e26ea2cffffe50bd4f0bdb4594af9cc4510386d29c715c2b4ea99c6522838a08cc2045bf65e8b1da01ab33a266fc9f03da42e28b8cc4d5c030001777ab077e3

diff --git a/sci-electronics/geda/geda-1.10.2.ebuild b/sci-electronics/geda/geda-1.10.2.ebuild
new file mode 100644
index 000000000000..3f4d3e11c4d2
--- /dev/null
+++ b/sci-electronics/geda/geda-1.10.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DOCS_BUILDER="doxygen"
+DOCS_DEPEND="media-gfx/graphviz"
+inherit autotools docs xdg
+
+MY_PN=${PN}-gaf
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="GPL Electronic Design Automation (gEDA):gaf core package"
+HOMEPAGE="http://wiki.geda-project.org/geda:gaf"
+SRC_URI="http://ftp.geda-project.org/${MY_PN}/stable/v$(ver_cut 1-2)/${PV}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug examples fam nls stroke threads"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-scheme/guile
+	sci-electronics/electronics-menu
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	nls? ( virtual/libintl )
+	stroke? ( dev-libs/libstroke )
+	fam? ( app-admin/gamin )
+"
+
+DEPEND="${RDEPEND}
+	dev-util/desktop-file-utils
+	x11-misc/shared-mime-info"
+BDEPEND="
+	sys-apps/groff
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	default
+
+	if ! use doc ; then
+		sed -i -e '/^SUBDIRS = /s/docs//' Makefile.in || die
+	fi
+	if ! use examples ; then
+		sed -i -e 's/\texamples$//' Makefile.in || die
+	fi
+
+	# add missing GIO_LIB Bug #684870
+	sed -i -e 's/gsymcheck_LDFLAGS =/gsymcheck_LDFLAGS = $(GIO_LIBS)/' \
+		gsymcheck/src/Makefile.am || die
+
+	sed -i -e 's/gnetlist_LDFLAGS =/gnetlist_LDFLAGS = $(GIO_LIBS)/' \
+		gnetlist-legacy/src/Makefile.am || die
+
+	sed -i -e 's/gschlas_LDFLAGS =/gschlas_LDFLAGS = $(GIO_LIBS)/' \
+		utils/gschlas/Makefile.am || die
+
+	sed -i -e 's/sarlacc_schem_LDFLAGS =/sarlacc_schem_LDFLAGS = $(GIO_LIBS)/' \
+		contrib/sarlacc_schem/Makefile.am || die
+
+	# remove compressed files, compressed by portage in install phase
+	rm docs/wiki/media/geda/gsch2pcb-libs.tar.gz || die
+	rm docs/wiki/media/geda/pcb_plugin_template.tar.gz || die
+	rm docs/wiki/media/pcb/plugin_debug_window.tar.gz || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-rpath
+		--disable-update-xdg-database
+		$(use_enable doc doxygen)
+		$(use_enable debug assert)
+		$(use_enable nls)
+		$(use_enable threads threads posix)
+		$(use_with stroke libstroke)
+		$(use_with fam libfam)
+	)
+
+	econf "${myconf[@]}"
+}