[gentoo-commits] repo/gentoo:master commit in: dev-java/fec/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     6a9f097fd330dbeabd61d6072e159c77b2202e7d
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Mon Dec 27 15:14:47 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Thu Feb 24 09:37:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a9f097f

dev-java/fec: EAPI 8, switch to log4j-12-api:2

Closes: https://bugs.gentoo.org/830919
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/24106/commits/49b7cffc2fa2d91fb9dc424c5c44ba0874600ecc
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-java/fec/fec-1.0.4-r4.ebuild | 68 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/dev-java/fec/fec-1.0.4-r4.ebuild b/dev-java/fec/fec-1.0.4-r4.ebuild
new file mode 100644
index 000000000000..29f4fada481c
--- /dev/null
+++ b/dev-java/fec/fec-1.0.4-r4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+JAVA_PKG_IUSE="doc source"
+
+inherit flag-o-matic toolchain-funcs java-pkg-2 java-ant-2
+
+DESCRIPTION="Forward Error Correction library in Java"
+HOMEPAGE="https://bitbucket.org/onionnetworks/"
+SRC_URI="https://dev.gentoo.org/~monsieurp/packages/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+CDEPEND="dev-java/log4j-12-api:2"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*"
+
+PATCHES=(
+	"${FILESDIR}"/"${P}-libfec8path.patch"
+	"${FILESDIR}"/"${P}-build.patch"
+	"${FILESDIR}"/"${P}-soname.patch"
+	"${FILESDIR}"/"${P}-remove-concurrent-util-imports.patch"
+)
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+JAVA_ANT_CLASSPATH_TAGS="javac javadoc"
+EANT_GENTOO_CLASSPATH="log4j-12-api-2"
+EANT_BUILD_TARGET="jars"
+
+# There seems to be unit tests, but they are in such a state.
+RESTRICT="test"
+
+src_prepare() {
+	# Apply patches.
+	default
+
+	# In fact, we'll wipe tests altogether.
+	rm -rf tests || die
+
+	# Get rid of bundled jars.
+	java-pkg_clean
+}
+
+src_compile() {
+	java-pkg-2_src_compile
+	einfo "Sucessfully compiled Java classes!"
+
+	cd "${S}"/src/csrc || die
+	append-flags -fPIC
+	emake CC=$(tc-getCC) CFLAGS="${CFLAGS} $(java-pkg_get-jni-cflags)"
+	einfo "Sucessfully compiled C files!"
+}
+
+src_install() {
+	java-pkg_newjar "lib/onion-${PN}.jar" "${PN}.jar"
+	use doc && java-pkg_dojavadoc javadoc
+	use source && java-pkg_dosrc src/com
+	dolib.so src/csrc/libfec{8,16}.so
+}