[gentoo-commits] repo/gentoo:master commit in: media-libs/openimageio/

["Sam James" <sam@gentoo.org>]

commit:     08b292cf5f458c385970a1510edf6ed3015c3876
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 12 03:50:08 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 12 03:55:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08b292cf

media-libs/openimageio: add 2.3.12.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/openimageio/Manifest                    |   1 +
 media-libs/openimageio/openimageio-2.3.12.0.ebuild | 190 +++++++++++++++++++++
 2 files changed, 191 insertions(+)

diff --git a/media-libs/openimageio/Manifest b/media-libs/openimageio/Manifest
index 06529c0e6348..e75be6bbbc01 100644
--- a/media-libs/openimageio/Manifest
+++ b/media-libs/openimageio/Manifest
@@ -1,4 +1,5 @@
 DIST openimageio-2.2.18.0.tar.gz 29246567 BLAKE2B cb7297028b39b1616962b94aff61f0240b88beeae216c6e39f450cb860660b2c844393a759302dfd325ba95336e06944ad72acfb0e87aa2b1cadfe658bd6bdaa SHA512 22a61e8b1ca098c2293e972372d02f0ac8ce54b46eb957b1ffcacb9e0ca4ff13f560d67804e0db0a898d8bec2fdb73f3cdcd1ee1867f92f97f84c1c111e535be
 DIST openimageio-2.3.11.0.tar.gz 32439595 BLAKE2B 6e64284c36de87fc077e839db808d4fab0cb6ea4951639cfed21e68900782c03ef6c2e64dcae5c1bf9360ad0a838ee36396d31634ad0ddd20f8fc9f683fc9dc8 SHA512 7e973f4f1b00dfc2486d074f5fdd03aa612a650411c7440868a4846ecfda8b172be33110fce35801dfed92d80f338b989f3ee001191938c48edef5ca760eff3c
+DIST openimageio-2.3.12.0.tar.gz 32452689 BLAKE2B f5fd428c597b573586a4749b56225ad3c035ab1c2122ff3e93df8e90be5796cc57978aa9fc5b102f2cf64d2407e70a11683b5bbee118c9fac3536b965ed044cc SHA512 c8ec0ead8396717b218d937b9193ef9162c68446f6f1d477f3f0ee4b5656c3d7d53b58bf55aa300fbf57d367a47d795861b5683157e0d0271e0ea56f0460c58d
 DIST openimageio-oexr-test-image-f17e353fbfcde3406fe02675f4d92aeae422a560.tar.gz 252226183 BLAKE2B b94fb08515e18821e5b88c10031ca53675c56f96397e00b4e186d8dfb9f8557bc935ff102d61835590dca6deeef90dba03b81fd76a7958ab4d0592c042c2130a SHA512 26b9b2cda9d48554b8a53f06bc20301f8ff77dc5e1d7caf9ec45aaaefd8578d3d4d4b2e0a1d1b0f697805fdc0c5d4bae4948cea21821df3006ac0f8b9020f85f
 DIST openimageio-oiio-test-image-b85d7a3a10a3256b50325ad310c33e7f7cf2c6cb.tar.gz 137513393 BLAKE2B ebde02d57daaa58c08c7aab2251c39eefd5b736e1cc4a6d28603d8ee52b7828fa7529c9616207b8b0bcb04d88cd4c60c6325e6f09b4f3410dd6e61c5532b04ad SHA512 840a6785779d85f5da052cb635a92c27451e464414fefd2faaf5fc7a6b78936ff05a6a960c07bb968d7c18e753053ff0f425505de54577d30620fbff9be043fb

diff --git a/media-libs/openimageio/openimageio-2.3.12.0.ebuild b/media-libs/openimageio/openimageio-2.3.12.0.ebuild
new file mode 100644
index 000000000000..445eb5f23ac9
--- /dev/null
+++ b/media-libs/openimageio/openimageio-2.3.12.0.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+FONT_PN=OpenImageIO
+PYTHON_COMPAT=( python3_{8..10} )
+
+TEST_OIIO_IMAGE_COMMIT="b85d7a3a10a3256b50325ad310c33e7f7cf2c6cb"
+TEST_OEXR_IMAGE_COMMIT="f17e353fbfcde3406fe02675f4d92aeae422a560"
+inherit cmake font python-single-r1 flag-o-matic
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="https://sites.google.com/site/openimageio/ https://github.com/OpenImageIO"
+SRC_URI="https://github.com/OpenImageIO/oiio/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" test? (
+		https://github.com/OpenImageIO/oiio-images/archive/${TEST_OIIO_IMAGE_COMMIT}.tar.gz -> ${PN}-oiio-test-image-${TEST_OIIO_IMAGE_COMMIT}.tar.gz
+		https://github.com/AcademySoftwareFoundation/openexr-images/archive/${TEST_OEXR_IMAGE_COMMIT}.tar.gz -> ${PN}-oexr-test-image-${TEST_OEXR_IMAGE_COMMIT}.tar.gz
+	)"
+S="${WORKDIR}/oiio-${PV}"
+
+LICENSE="BSD"
+# TODO: drop .1 on next SONAME change (2.3 -> 2.4?) as we needed to nudge it
+# for changing to openexr 3 which broke ABI.
+SLOT="0/$(ver_cut 1-2).1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+X86_CPU_FEATURES=(
+	aes:aes sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="dicom doc ffmpeg gif jpeg2k opencv opengl openvdb ptex python qt5 raw test +truetype ${CPU_FEATURES[@]%:*}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Not quite working yet
+RESTRICT="!test? ( test ) test"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-bibtexextra
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-fontutils
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexextra
+	)
+"
+RDEPEND="
+	>=dev-libs/boost-1.62:=
+	dev-cpp/robin-map
+	dev-libs/libfmt:=
+	dev-libs/pugixml:=
+	>=media-libs/libheif-1.7.0:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	media-libs/imath:=
+	media-libs/opencolorio:=
+	media-libs/openexr:3=
+	media-libs/tiff:0=
+	sys-libs/zlib:=
+	virtual/jpeg:0
+	dicom? ( sci-libs/dcmtk )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gif? ( media-libs/giflib:0= )
+	jpeg2k? ( >=media-libs/openjpeg-2.0:2= )
+	opencv? ( media-libs/opencv:= )
+	opengl? (
+		media-libs/glew:=
+		virtual/glu
+		virtual/opengl
+	)
+	openvdb? (
+		dev-cpp/tbb:=
+		media-gfx/openvdb:=
+	)
+	ptex? ( media-libs/ptex:= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	raw? ( media-libs/libraw:= )
+	truetype? ( media-libs/freetype:2= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES.md CREDITS.md README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.3.11.0-imath-openexr-3.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Note: on bumps, please try again with OpenEXR 3 + ilmmath!
+	# Sabotage finding OpenEXR 3 for now to force usage of OpenEXR 2
+	# (because it mix and matches which version it uses; sed this to
+	# make sure it'll use OpenEXR 3 if it can, but it won't.)
+	# bug #821193
+	#sed -i \
+	#	-e 's/find_package(OpenEXR CONFIG)/find_package(OpenEXR-3 CONFIG)/' \
+	#	src/cmake/modules/FindOpenEXR.cmake || die
+
+	cmake_src_prepare
+	cmake_comment_add_subdirectory src/fonts
+
+	if use test ; then
+		mkdir -p "${BUILD_DIR}"/testsuite || die
+		mv "${WORKDIR}"/oiio-images-${TEST_OIIO_IMAGE_COMMIT} "${BUILD_DIR}"/testsuite/oiio-images || die
+		mv "${WORKDIR}"/openexr-images-${TEST_OEXR_IMAGE_COMMIT} "${BUILD_DIR}"/testsuite/openexr-images || die
+	fi
+}
+
+src_configure() {
+	# Build with SIMD support
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	append-cppflags -DOIIO_USING_OPENEXR_3
+
+	local mycmakeargs=(
+		-DVERBOSE=ON
+		-DBUILD_TESTING=$(usex test)
+		-DOIIO_BUILD_TESTS=$(usex test)
+		-DINSTALL_FONTS=OFF
+		-DBUILD_DOCS=$(usex doc)
+		-DINSTALL_DOCS=$(usex doc)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_CCACHE=OFF
+		-DUSE_DCMTK=$(usex dicom)
+		-DUSE_EXTERNAL_PUGIXML=ON
+		-DUSE_JPEGTURBO=ON
+		-DUSE_NUKE=OFF # not in Gentoo
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_GIF=$(usex gif)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENCV=$(usex opencv)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_OPENVDB=$(usex openvdb)
+		-DUSE_PTEX=$(usex ptex)
+		-DUSE_PYTHON=$(usex python)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_LIBRAW=$(usex raw)
+		-DUSE_FREETYPE=$(usex truetype)
+		-DUSE_SIMD=$(local IFS=','; echo "${mysimd[*]}")
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DPYTHON_VERSION=${EPYTHON#python}
+			-DPYTHON_SITE_DIR=$(python_get_sitedir)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# can't use font_src_install
+	# it does directory hierarchy recreation
+	FONT_S=(
+		"${S}/src/fonts/Droid_Sans"
+		"${S}/src/fonts/Droid_Sans_Mono"
+		"${S}/src/fonts/Droid_Serif"
+	)
+	insinto ${FONTDIR}
+	for dir in "${FONT_S[@]}"; do
+		doins "${dir}"/*.ttf
+	done
+}