[gentoo-commits] repo/gentoo:master commit in: mail-client/evolution/

["Matt Turner" <mattst88@gentoo.org>]

commit:     7386a9aa47abcfc5074977e500677f8f80bf0614
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 11 20:23:33 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Feb 11 20:56:02 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7386a9aa

mail-client/evolution: Version bump to 3.42.4

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 mail-client/evolution/Manifest                |   1 +
 mail-client/evolution/evolution-3.42.4.ebuild | 151 ++++++++++++++++++++++++++
 2 files changed, 152 insertions(+)

diff --git a/mail-client/evolution/Manifest b/mail-client/evolution/Manifest
index 0724a06418de..5e81605acc13 100644
--- a/mail-client/evolution/Manifest
+++ b/mail-client/evolution/Manifest
@@ -1,2 +1,3 @@
 DIST evolution-3.40.4.tar.xz 12219300 BLAKE2B cbe56014252e8a23debbd4055be85d8bf89e25aa677b92880a6dba78d5d5fbb452403d5f9199b0257ca4c7ee10bff3bc5ca7601fa74390cf6d01d4d7cf099d1d SHA512 f6f08ab3cbc21397a0727b1edc5e37711294fdba6e537000d5a9f11f0142f69702fffad3922645fab256ccdee348b914a87abd0e6ed843c01762ccd32333518a
 DIST evolution-3.42.3.tar.xz 12280864 BLAKE2B e2644bb45efa63aa9a4af2747fa7a70c728f92c1a7207758b3b4bd4cb7bc1d54a955ab40a63dc94fc134ba37acfd52da37fcd7397153db42a41b2a1376f1c26b SHA512 4824b46fcd1537e38faeb91095b8a9330fa116cbec73641bbb8fe2e302a0f87f06d7c744970f3705d88e7aa07d63a2195039a917c5c3047678bb2be0e9526580
+DIST evolution-3.42.4.tar.xz 12285100 BLAKE2B dd02c84f4eb868b8a266b5d9a2383e16c095c073cd2849b96bee842b8ed67f0af803f14a867202321ad373148f80de142baf7c05b96bf4c84a62f881f5b26c8f SHA512 4319d19089269e53bb751408d5cec1609a245dd366a30ad6e2e117f074ff0b2f55228a5dbcc9af661846a253c0860a61a8648bd582b395851e21e152ffe0b1aa

diff --git a/mail-client/evolution/evolution-3.42.4.ebuild b/mail-client/evolution/evolution-3.42.4.ebuild
new file mode 100644
index 000000000000..460604af5b5e
--- /dev/null
+++ b/mail-client/evolution/evolution-3.42.4.ebuild
@@ -0,0 +1,151 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake gnome2 readme.gentoo-r1
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
+SLOT="2.0"
+
+IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+# glade-3 support is for maintainers only per configure.ac
+# pst is not mature enough and changes API/ABI frequently
+# dconf explicitely needed for backup plugin
+# gnome-desktop support is optional with --enable-gnome-desktop
+# automagic libunity dep
+# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
+DEPEND="
+	>=app-crypt/gcr-3.4:=[gtk]
+	>=app-text/enchant-2.2.0:2
+	>=dev-libs/glib-2.56:2[dbus]
+	>=dev-libs/libxml2-2.7.3:2
+	>=gnome-base/gnome-desktop-2.91.3:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
+	>=media-libs/libcanberra-0.25[gtk3]
+	>=net-libs/libsoup-2.42:2.4
+	>=net-libs/webkit-gtk-2.28.0:4[spell?]
+	>=x11-libs/cairo-1.9.15:=[glib]
+	>=x11-libs/gdk-pixbuf-2.24:2
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/libnotify-0.7:=
+	>=x11-misc/shared-mime-info-0.22
+
+	>=app-text/iso-codes-0.49
+	dev-libs/atk
+	gnome-base/dconf
+	x11-libs/libSM
+	x11-libs/libICE
+
+	archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
+	bogofilter? ( mail-filter/bogofilter )
+	geolocation? (
+		>=media-libs/libchamplain-0.12:0.12[gtk]
+		>=media-libs/clutter-1.0.0:1.0
+		>=media-libs/clutter-gtk-0.90:1.0
+		>=sci-geosciences/geocode-glib-3.10.0 )
+	ldap? ( >=net-nds/openldap-2:= )
+	spamassassin? ( mail-filter/spamassassin )
+	spell? ( >=app-text/gspell-1.8:= )
+	ssl? (
+		>=dev-libs/nspr-4.6.1:=
+		>=dev-libs/nss-3.11:= )
+	weather? ( >=dev-libs/libgweather-3.10:2= )
+	ytnef? ( net-mail/ytnef )
+"
+RDEPEND="${DEPEND}
+	highlight? ( app-text/highlight )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	>=dev-util/intltool-0.40.0
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
+~/.local/share/applications/mimeapps.list so it includes the
+following content:
+
+[Default Applications]
+x-scheme-handler/http=firefox.desktop
+x-scheme-handler/https=firefox.desktop
+
+(replace firefox.desktop with the name of the appropriate .desktop
+file from /usr/share/applications if you use a different browser)."
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Use NSS/NSPR only if 'ssl' is enabled.
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DENABLE_SMIME=$(usex ssl)
+		-DENABLE_GNOME_DESKTOP=ON
+		-DWITH_ENCHANT_VERSION=2
+		-DENABLE_CANBERRA=ON
+		-DENABLE_AUTOAR=$(usex archive)
+		-DWITH_HELP=ON
+		-DENABLE_YTNEF=OFF
+		-DWITH_BOGOFILTER=$(usex bogofilter)
+		-DWITH_SPAMASSASSIN=$(usex spamassassin)
+		-DENABLE_GSPELL=$(usex spell)
+		-DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_CONTACT_MAPS=$(usex geolocation)
+		-DENABLE_YTNEF=$(usex ytnef)
+		-DENABLE_PST_IMPORT=OFF
+		-DWITH_GLADE_CATALOG=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	# Problems with prelink:
+	# https://bugzilla.gnome.org/show_bug.cgi?id=731680
+	# https://bugzilla.gnome.org/show_bug.cgi?id=732148
+	# https://bugzilla.redhat.com/show_bug.cgi?id=1114538
+	echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
+	doenvd "${T}"/99${PN}
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}