From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1362199-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id B89A2158087
	for <garchives@archives.gentoo.org>; Fri, 28 Jan 2022 11:16:40 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 0D2BD2BC08B;
	Fri, 28 Jan 2022 11:16:39 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id B16E62BC06D
	for <gentoo-commits@lists.gentoo.org>; Fri, 28 Jan 2022 11:16:38 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 649BB342DA7
	for <gentoo-commits@lists.gentoo.org>; Fri, 28 Jan 2022 11:16:37 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id C81062AF
	for <gentoo-commits@lists.gentoo.org>; Fri, 28 Jan 2022 11:16:35 +0000 (UTC)
From: "Arthur Zamarin" <arthurzam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Arthur Zamarin" <arthurzam@gentoo.org>
Message-ID: <1643368582.6c7a12b0c171c1c7a487b650f81646acc9d9bf07.arthurzam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/buildbot-worker/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-util/buildbot-worker/Manifest dev-util/buildbot-worker/buildbot-worker-3.4.0.ebuild
X-VCS-Directories: dev-util/buildbot-worker/
X-VCS-Committer: arthurzam
X-VCS-Committer-Name: Arthur Zamarin
X-VCS-Revision: 6c7a12b0c171c1c7a487b650f81646acc9d9bf07
X-VCS-Branch: master
Date: Fri, 28 Jan 2022 11:16:35 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: b2346a7e-708c-4ecf-be35-9fe5ffe0b5e4
X-Archives-Hash: 808851d1056afc4c8c3fd477206f3d1a

commit:     6c7a12b0c171c1c7a487b650f81646acc9d9bf07
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 27 20:57:09 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 28 11:16:22 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c7a12b0

dev-util/buildbot-worker: add 3.4.0, enable py3.10, cleanup

Closes: https://bugs.gentoo.org/814956
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-util/buildbot-worker/Manifest                  |   1 +
 .../buildbot-worker/buildbot-worker-3.4.0.ebuild   | 124 +++++++++++++++++++++
 2 files changed, 125 insertions(+)

diff --git a/dev-util/buildbot-worker/Manifest b/dev-util/buildbot-worker/Manifest
index e785c6ec5448..bd0177bf8ae4 100644
--- a/dev-util/buildbot-worker/Manifest
+++ b/dev-util/buildbot-worker/Manifest
@@ -7,3 +7,4 @@ DIST buildbot-worker-3.1.0.tar.gz 97938 BLAKE2B a886656ad099a849731307ce5db4eea0
 DIST buildbot-worker-3.1.1.tar.gz 98239 BLAKE2B e73abcdd0fb067da0e77bf8382f8d4d54c0db63e3cf04d003599dc68dfe5c742758ba2c3e39368413a45e8c5beb913a4cf5571e229c3ce5084066790702fb4e8 SHA512 9bf969aadf0f2ccea726365b1e250ebd0c0d0146b4fb1b49ae675e0db555a0b50a87ceb455c25f987b75605d72ab50306f5af9247978fe93270d2c97b8ed04dd
 DIST buildbot-worker-3.2.0.tar.gz 99401 BLAKE2B e50ee76f667aab2a07647df3bd1dfd2016827bc5bf96be5f2f6e90158790c3b908f0c5b88fead59bf9977dc15adbe275c7ba81829c56fde3c1c318084633624f SHA512 c7822c16761052f2b45b809de3d3ff910f40679d885213541aa87f54a3490e9a092152f9cbb8c4ab25d1e5b2c9597e87b202f0db62c79f35e8fec2cfcc797653
 DIST buildbot-worker-3.3.0.tar.gz 99996 BLAKE2B 4e2bbe6467fc58a9f8c597939cdcfd4538712445580ab7f2c0e1ce3415cc1f8c60ce2b3cba4c16f341d8c19e1b99a91e799c7d3ff2343af0fffa0a1740960588 SHA512 e75a7a91a5b2c418dae65abdd1dde2b840a840e5b9cc1a218007a9e33e1cd58288bc708ec43ecfd9ec74a257809a59f65923ec8dc8aee1ef28cfaf82314964e3
+DIST buildbot-worker-3.4.0.tar.gz 102910 BLAKE2B c38a806e8d0475a8c18176310f628b829fc359f013b315e82715e71071213fe4a0cdf38273ad7df39a66675f4ebc9fb1881fb990290f2bbedf4c8777ec93d4dc SHA512 411a2bf496622c2b9a3e0dea1ea8a71b347566010086c57ffc5d1114546cc5052af39a8ff7b10ffe6e7afdb6fc8ff73a9ffba23b96a76ff1cc0e3eff81cc59a7

diff --git a/dev-util/buildbot-worker/buildbot-worker-3.4.0.ebuild b/dev-util/buildbot-worker/buildbot-worker-3.4.0.ebuild
new file mode 100644
index 000000000000..69a126362a82
--- /dev/null
+++ b/dev-util/buildbot-worker/buildbot-worker-3.4.0.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit readme.gentoo-r1 distutils-r1
+
+MY_V="${PV/_p/.post}"
+MY_P="${PN}-${MY_V}"
+
+DESCRIPTION="BuildBot Worker (slave) Daemon"
+HOMEPAGE="https://buildbot.net/
+	https://github.com/buildbot/buildbot
+	https://pypi.org/project/buildbot-worker/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/buildbot
+	>=dev-python/twisted-17.9.0[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	!<dev-util/buildbot-1.0.0
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+DOC_CONTENTS="The \"buildbot\" user and the \"buildbot_worker\" init script has been added
+to support starting buildbot_worker through Gentoo's init system. To use this,
+execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+Set up your build worker following the documentation, make sure the
+resulting directories are owned by the \"buildbot\" user and point
+\"${ROOT}/etc/conf.d/buildbot_worker.myinstance\" at the right location.
+The scripts can	run as a different user if desired."
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial buildbot_worker || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman docs/buildbot-worker.1
+
+	newconfd "${FILESDIR}/buildbot_worker.confd2" buildbot_worker
+	newinitd "${FILESDIR}/buildbot_worker.initd2" buildbot_worker
+
+	dodir /var/lib/buildbot_worker
+	cp "${FILESDIR}/buildbot.tac.sample" "${D}/var/lib/buildbot_worker"|| die "Install failed!"
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	if [[ -n ${REPLACING_VERSIONS} ]]; then
+		ewarn
+		ewarn "More than one instance of a buildbot_worker can be run simultaneously."
+		ewarn " Note that \"BASEDIR\" in the buildbot_worker configuration file"
+		ewarn "is now the common base directory for all instances. If you are migrating from an older"
+		ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+		ewarn "The name of the subdirectory corresponds to the name of the buildbot_worker instance."
+		ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+		ewarn "    ln --symbolic --relative /etc/init.d/buildbot_worker /etc/init.d/buildbot_worker.myinstance"
+		ewarn "    rc-update add buildbot_worker.myinstance default"
+		ewarn "    /etc/init.d/buildbot_worker.myinstance start"
+		ewarn "Systems using systemd can do the following:"
+		ewarn "    systemctl enable buildbot_worker@myinstance.service"
+		ewarn "    systemctl enable buildbot_worker.target"
+		ewarn "    systemctl start buildbot_worker.target"
+	fi
+}
+
+pkg_config() {
+	local buildworker_path="/var/lib/buildbot_worker"
+	local log_path="/var/log/buildbot_worker"
+
+	einfo "This will prepare a new buildbot_worker instance in ${buildworker_path}."
+	einfo "Press Control-C to abort."
+
+	einfo "Enter the name for the new instance: "
+	read instance_name
+	[[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+	local instance_path="${buildworker_path}/${instance_name}"
+	local instance_log_path="${log_path}/${instance_name}"
+
+	if [[ -e "${instance_path}" ]]; then
+		eerror "The instance with the specified name already exists:"
+		eerror "${instance_path}"
+		die "Instance already exists"
+	fi
+
+	if [[ ! -d "${instance_path}" ]]; then
+		mkdir --parents "${instance_path}" || die "Unable to create directory ${buildworker_path}"
+	fi
+	chown --recursive buildbot:buildbot "${instance_path}" || die "Setting permissions for instance failed"
+	cp "${buildworker_path}/buildbot.tac.sample" "${instance_path}/buildbot.tac" \
+		|| die "Moving sample configuration failed"
+	ln --symbolic --relative "/etc/init.d/buildbot_worker" "/etc/init.d/buildbot_worker.${instance_name}" \
+		|| die "Unable to create link to init file"
+
+	if [[ ! -d "${instance_log_path}" ]]; then
+		mkdir --parents "${instance_log_path}" || die "Unable to create directory ${instance_log_path}"
+		chown --recursive buildbot:buildbot "${instance_log_path}" \
+			|| die "Setting permissions for instance failed"
+	fi
+	ln --symbolic --relative "${instance_log_path}/twistd.log" "${instance_path}/twistd.log" \
+		|| die "Unable to create link to log file"
+
+	einfo "Successfully created a buildbot_worker instance at ${instance_path}."
+	einfo "To change the default settings edit the buildbot.tac file in this directory."
+}