[gentoo-commits] repo/gentoo:master commit in: gnome-base/nautilus/

["Matt Turner" <mattst88@gentoo.org>]

commit:     2358e1d117630476cddb102ba78e2a417c7185f1
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 13 22:21:51 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Jan 13 22:33:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2358e1d1

gnome-base/nautilus: Version bump to 41.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-base/nautilus/Manifest             |   1 +
 gnome-base/nautilus/nautilus-41.2.ebuild | 108 +++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/gnome-base/nautilus/Manifest b/gnome-base/nautilus/Manifest
index b3a1b26e4bd8..7f73419708d3 100644
--- a/gnome-base/nautilus/Manifest
+++ b/gnome-base/nautilus/Manifest
@@ -1,2 +1,3 @@
 DIST nautilus-40.2.tar.xz 3250384 BLAKE2B 8f8bb0c1a060d57695b28df126d421f386d634cbeea007ca30e076eb1b432a4098b98e9a1f39f688f8a920d99ef42ae2d53fe14fb270ba1e7de16aadd037a8d7 SHA512 ff7beab2963231c6e5ccd88098260659dd7fedd38ef6c0b95d66ffa110bfe5adc86477e2c1657eb2fcfe6110384038f75a7e669158712dfc1e2bd3f9e273b268
 DIST nautilus-41.1.tar.xz 3246356 BLAKE2B 558cac6bacd4d4238e8ceb792baa4d85a6aa981e78ae380b6c1256d079cac8e78b3d9b850a01180e4952630eb7898b987f79c12844adca82ab3702b0213d3150 SHA512 1eb2f2a0187f8b6581fe64285f347e8522b971eeb4d1f575387f3767e177f0195e758da9187090155216807b8f49ebed0fbcc29dd3cce6f3e408d7a955ae5286
+DIST nautilus-41.2.tar.xz 3248212 BLAKE2B be4e4e8fc03751259a1a5d4d1eb726e3026d24376da3fa680c412598219bfb3ced52f9b809004913dffdb9bb1c176dede07288c440c100487b3a337d8eaab417 SHA512 adb14fa1cf37a4797f57ae5162bddcd5b012de270cf955051b69276bc266b1dbfd8027b835f627ae19a1252356b344b1c8a4b7ca79a22512f3138a2c13fd2f3e

diff --git a/gnome-base/nautilus/nautilus-41.2.ebuild b/gnome-base/nautilus/nautilus-41.2.ebuild
new file mode 100644
index 000000000000..d5d9b1ae7f2e
--- /dev/null
+++ b/gnome-base/nautilus/nautilus-41.2.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="Default file manager for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Nautilus"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0"
+IUSE="gnome +gstreamer gtk-doc +introspection +previewer selinux sendto"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	>=dev-libs/glib-2.67.1:2
+	>=media-libs/gexiv2-0.10.0
+	gstreamer? ( media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+	>=app-arch/gnome-autoar-0.3.0
+	>=gnome-base/gnome-desktop-3.0.0:3=
+	>=x11-libs/gtk+-3.22.27:3[X,introspection?]
+	>=gui-libs/libhandy-1.1.90:1
+	>=x11-libs/pango-1.28.3
+	selinux? ( >=sys-libs/libselinux-2.0 )
+	>=app-misc/tracker-3.0:3=
+	x11-libs/libX11
+	>=dev-libs/libxml2-2.7.8:2
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gstreamer? ( !<media-video/totem-3.31.91[nautilus] )
+	>=app-misc/tracker-miners-3.0:3=
+" # uses org.freedesktop.Tracker.Miner.Files gsettings schema from tracker-miners
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.51.2
+	>=dev-util/meson-0.57.2
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+PDEPEND="
+	gnome? ( x11-themes/adwaita-icon-theme )
+	previewer? ( >=gnome-extra/sushi-0.1.9 )
+	sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
+	>=gnome-base/gvfs-1.14[gtk(+)]
+" # Need gvfs[gtk] for recent:/// support; always built (without USE=gtk) since gvfs-1.34
+
+PATCHES=(
+	"${FILESDIR}"/3.30.5-docs-build.patch # Always install pregenerated manpage, keeping docs option for gtk-doc
+	"${FILESDIR}"/41.1-optional-gstreamer.patch # Allow controlling audio-video-properties build
+)
+
+src_prepare() {
+	if use previewer; then
+		DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
+			To activate the previewer, select a file and press space; to
+			close the previewer, press space again."
+	fi
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dextensions=true # image file properties, sendto support; also required for -Dgstreamer=true
+		$(meson_use gstreamer) # gstreamer audio-video-properties extension
+		$(meson_use introspection)
+		-Dlibportal=false # As of 40.2, all libportal usages are flatpak-specific
+		-Dpackagekit=false
+		$(meson_use selinux)
+		-Dprofiling=false
+		-Dtests=$(usex test all none)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	use previewer && readme.gentoo_create_doc
+	meson_src_install
+}
+
+src_test() {
+	gnome2_environment_reset # Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if use previewer; then
+		readme.gentoo_print_elog
+	else
+		elog "To preview media files, emerge nautilus with USE=previewer"
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}