[gentoo-commits] repo/gentoo:master commit in: net-libs/tox/

["Sam James" <sam@gentoo.org>]

commit:     f507f98aca30fe012a14ee6060a9001766aae94a
Author:     Josiah Mullins <JoMull01 <AT> protonmail <DOT> com>
AuthorDate: Tue Dec 21 21:22:45 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan  7 05:06:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f507f98a

net-libs/tox: Bump to version 0.2.13.

Signed-off-by: Josiah Mullins <JoMull01 <AT> protonmail.com>
Bug: https://bugs.gentoo.org/829650
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-libs/tox/Manifest          |   1 +
 net-libs/tox/tox-0.2.13.ebuild | 114 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index e976a4f2d42d..e5f406e55e51 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1 +1,2 @@
 DIST c-toxcore-0.2.12.tar.gz 504832 BLAKE2B 625713142cc1e4b6583879144c05d47a40a1d98031a8a2bf0deec85a199f816a0ff6df5c76e9487a526d7c1c1650b37a10ed81be8233eaa1395707851378474f SHA512 c22f139cfff3a5aedf5fb08c33cae0dae3d6fbceec87867c81290e3bf9d2e13466a0e2bad8378a7a7ba1e9b7b9ad756712963461ae248102e4cab7d4691228d8
+DIST c-toxcore-0.2.13.tar.gz 511533 BLAKE2B 8c68180710e3d06eaaef9fc05dc0ff2492907586934d1d6f57f147e07bb78b262f78b0057911e4b5cd27d2d1efb51cb714f757b90caa269988e604cafa62cd00 SHA512 f4ed9ea4afb7f9c14a5afd949f3a52e7880838c910acaf5adc39acb09ad574406be08f43b76a9fbdd4fc4bd14f0d73212dc7bd10783565055c910c6c3e5e357a

diff --git a/net-libs/tox/tox-0.2.13.ebuild b/net-libs/tox/tox-0.2.13.ebuild
new file mode 100644
index 000000000000..e05b2ca9cd78
--- /dev/null
+++ b/net-libs/tox/tox-0.2.13.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake systemd
+
+MY_P="c-toxcore-${PV}"
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat https://github.com/TokTok/c-toxcore"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.2"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon dht-node ipv6 log-debug +log-error log-info log-trace log-warn test"
+
+REQUIRED_USE="?? ( log-debug log-error log-info log-trace log-warn )
+		daemon? ( dht-node )"
+RESTRICT="!test? ( test )"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	dev-libs/libsodium:=[asm,urandom,-minimal]
+	av? (
+		media-libs/libvpx:=
+		media-libs/opus
+	)
+	daemon? ( dev-libs/libconfig:= )"
+RDEPEND="
+	${DEPEND}
+	daemon? (
+		acct-group/tox
+		acct-user/tox
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cmake_src_prepare
+
+	#Remove faulty tests
+	for testname in lan_discovery save_compatibility set_status_message; do
+		sed -i -e "/^auto_test(${testname})$/d" CMakeLists.txt || die
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAUTOTEST=$(usex test ON OFF)
+		-DBOOTSTRAP_DAEMON=$(usex daemon ON OFF)
+		-DBUILD_MISC_TESTS=$(usex test ON OFF)
+		-DBUILD_TOXAV=$(usex av ON OFF)
+		-DDHT_BOOTSTRAP=$(usex dht-node ON OFF)
+		-DENABLE_SHARED=ON
+		-DENABLE_STATIC=OFF
+		-DMUST_BUILD_TOXAV=$(usex av ON OFF)
+	)
+
+	if use test; then
+		mycmakeargs+=(
+			-DTEST_TIMEOUT_SECONDS=150
+			-DUSE_IPV6=$(usex ipv6 ON OFF)
+		)
+	else
+		mycmakeargs+=(-DUSE_IPV6=OFF)
+	fi
+
+	if use log-trace; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="TRACE")
+	elif use log-debug; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="DEBUG")
+	elif use log-info; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="INFO")
+	elif use log-warn; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="WARNING")
+	elif use log-error; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="ERROR")
+	else
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="")
+		einfo "Logging disabled"
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_src_test -j1
+}
+
+src_install() {
+	cmake_src_install
+
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+}
+
+pkg_postinst() {
+	if use dht-node; then
+		ewarn "The QA notice regarding libmisc_tools.so is known by the upstream"
+		ewarn "developers and is on their TODO list. For more information,"
+		ewarn "please see 'https://github.com/toktok/c-toxcore/issues/1144'"
+		ewarn ""
+		ewarn "There is currently an unresolved issue with tox DHT Bootstrap node"
+		ewarn "that causes the program to be built with a null library reference."
+		ewarn "This causes an infinite loop for certain revdep-rebuild commands."
+		ewarn "If you aren't running a node, please consider disabling the dht-node use flag."
+	fi
+}