[gentoo-commits] repo/gentoo:master commit in: dev-python/translate-toolkit/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     53bb1f22184675a052d316de23e164c871454749
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  5 17:25:56 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Jan  5 17:25:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53bb1f22

dev-python/translate-toolkit: add 3.5.2

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/translate-toolkit/Manifest              |   1 +
 .../translate-toolkit-3.5.2.ebuild                 | 100 +++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index 5d7182fe4dec..071546ca44bf 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1 +1,2 @@
 DIST translate-3.5.1.gh.tar.gz 1147898 BLAKE2B f9fc96065727e0016e61fd581690dafc3021471de9ccc9012b223c24778669b984e0bf0ab5f83a910af0e543b0e4793afa110c5b2ced890a257f72512bcaf58d SHA512 2125e3ab019a6b721327d6979482562d5984df28b04aaa69d11e44b6a7396ee387f79d8242a20a84157f9b62457839b52599eb0fe13abac33c9a312a84d55d30
+DIST translate-3.5.2.gh.tar.gz 1147847 BLAKE2B 6ca8458975018c3645f3fcead99812b5f91c2a3e621060c1cf9599ecd2fdee8914ae1d70b70f8bc76f5d941f43e69e55555a35a5792d0c8c9d9e06458e670617 SHA512 e04c195d0f33aaf9c2368955c4c399be3c23702ce0fcb41705f727b65e129b652b5637a9b56ad2879f836548b77c266382ce41220a23aa9058828ee2f2ba1b3e

diff --git a/dev-python/translate-toolkit/translate-toolkit-3.5.2.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.5.2.ebuild
new file mode 100644
index 000000000000..768d499ebbb3
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.5.2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="
+	https://github.com/translate/translate/archive/refs/tags/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND=">=dev-python/six-1.11.0[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND+="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/translate-toolkit-3.3.0-no-install-docs.patch
+)
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}