[gentoo-commits] repo/gentoo:master commit in: dev-vcs/gitg/

["Michał Górny" <mgorny@gentoo.org>]

commit:     f99ff8ae560a5e371075308142a2bb35533874eb
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 30 08:13:20 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Dec 30 08:57:33 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f99ff8ae

dev-vcs/gitg: Bump to v41

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-vcs/gitg/Manifest       |  1 +
 dev-vcs/gitg/gitg-41.ebuild | 86 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
index 3d6f0c62a47f..854234ced112 100644
--- a/dev-vcs/gitg/Manifest
+++ b/dev-vcs/gitg/Manifest
@@ -1 +1,2 @@
 DIST gitg-3.32.1.tar.xz 10613836 BLAKE2B 43c2c37f5c06cb6155906d5988f0787334af7a9091e537fa7b0fc1a9de3138f261a3e3c578afc663c7b57a33f39c19318a53daf7896c465922138197c3bbb778 SHA512 243e630b3e5bb1919dc307e6b3fed1b1b0e3884d2a2507e4526b4af61e86f1cd7004a3dbb96001ffb0280cefe7cdb9b109c39996718913c7410224830c0145a4
+DIST gitg-41.tar.xz 10604696 BLAKE2B bc8a07565338f77a0a4706d6ff145ed09096acb0230fb160218a6374b87968ffde6615b6e2970ca9162ef542f877c3c8ab2023396c13e023cc47dd5bf466f22c SHA512 4e8fe0b1ab5302f975f58277e5ae42300a96d20bb1c41426d8c0e058a53420fcca73f75566f593f5aa2882b3a0e1608cdd542bc4f68c731153ba9185972d6f51

diff --git a/dev-vcs/gitg/gitg-41.ebuild b/dev-vcs/gitg/gitg-41.ebuild
new file mode 100644
index 000000000000..71351bd2d1d9
--- /dev/null
+++ b/dev-vcs/gitg/gitg-41.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+# vala-0.36 fails to build, https://bugs.gentoo.org/692538
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson python-r1 vala xdg-utils
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret[vala]
+	>=app-text/gspell-1[vala]
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/json-glib
+	dev-libs/libdazzle[vala]
+	dev-libs/libgee:0.8[introspection]
+	dev-libs/libgit2:=[threads]
+	>=dev-libs/libgit2-glib-1.0.0[ssh]
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-4.0.3:4
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-1.0.0[vala]
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	vala_src_prepare
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use glade glade_catalog)
+		# we install the module manually anyway
+		-Dpython=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgitg-ext/GitgExt.py
+	fi
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}