[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgit2-glib/

["Matt Turner" <mattst88@gentoo.org>]

commit:     58904bca826e14bd2eef270c904d85211c774a55
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 23 17:40:21 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Dec 23 17:45:02 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58904bca

dev-libs/libgit2-glib: Version bump to 1.0.0.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgit2-glib/Manifest                    |  1 +
 dev-libs/libgit2-glib/libgit2-glib-1.0.0.1.ebuild | 60 +++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/libgit2-glib/Manifest b/dev-libs/libgit2-glib/Manifest
index d50b3fb0e67c..99cf22959a87 100644
--- a/dev-libs/libgit2-glib/Manifest
+++ b/dev-libs/libgit2-glib/Manifest
@@ -1 +1,2 @@
 DIST libgit2-glib-0.99.0.1.tar.xz 140996 BLAKE2B 0c163467ea43ab236b2c856416940b1ed7c93e6ed8ce9980d2d146f0633830ab3765d8bd34bdaab31efdb4096e88e0513c9585b9e06a3efc800d5c32a0d29479 SHA512 48b34ba84b5315d23d0429a684753c3a64c62086d70a67fdb4dfbf8f2ee883f5a90d7e59cfcfd229682794c455b668eb9bd7bf6159d6bfa45a99ddc2461d7c25
+DIST libgit2-glib-1.0.0.1.tar.xz 141664 BLAKE2B a99ad6db55d0d4bee4d7d96b92e92d12712843e41e25e5ab57f5722926fe3e95109a33654d0ab94b7f919bd5d51a0b159dcae720eee763200c964d0327b8a37d SHA512 8e156791783f79d585fa83267a5e14a4a93324fcca75e836478ddd5b5c53d9e827b07a3738c67116478435613639aab0992f32413b9a4de5fc4ff641dd042e80

diff --git a/dev-libs/libgit2-glib/libgit2-glib-1.0.0.1.ebuild b/dev-libs/libgit2-glib/libgit2-glib-1.0.0.1.ebuild
new file mode 100644
index 000000000000..ed7a89a597ee
--- /dev/null
+++ b/dev-libs/libgit2-glib/libgit2-glib-1.0.0.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-r1 vala xdg
+
+DESCRIPTION="Git library for GLib"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="gtk-doc python +ssh +vala"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/gobject-introspection-1.54:=
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgit2-0.26.0:0=[ssh?]
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		-Dintrospection=true
+		-Dpython=false # we install python scripts manually
+		$(meson_use ssh)
+		$(meson_use vala vapi)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgit2-glib/Ggit.py
+	fi
+}