[gentoo-commits] repo/gentoo:master commit in: sys-power/bbswitch/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     1dba32c6c3436924b55e2352d16b04430110c2f8
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 21 18:51:59 2021 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Dec 21 18:54:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1dba32c6

sys-power/bbswitch: Bump to new snapshot

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 sys-power/bbswitch/Manifest                      |  1 +
 sys-power/bbswitch/bbswitch-0.8_p20211129.ebuild | 55 ++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/sys-power/bbswitch/Manifest b/sys-power/bbswitch/Manifest
index 2a7fb6d487ff..97f834f76331 100644
--- a/sys-power/bbswitch/Manifest
+++ b/sys-power/bbswitch/Manifest
@@ -1 +1,2 @@
 DIST bbswitch-0.8_p20200526.tar.gz 15869 BLAKE2B cdeaf539a0996f53d3add215fca1127321b7183526a248340177f4320171b92a5ce531eeedfb1da2f0d9f07c6b61e8cfb635a457406e477640f2e7090b29b655 SHA512 487bcd845d1f462e77b5b9e3f304cd28d0ddfd391ecc36de530a3d18d9d4932bc895ed29972e27006b6f3eeb50c37b523ef786a26b6ee75c19fa55288a496d4a
+DIST bbswitch-0.8_p20211129.tar.gz 15889 BLAKE2B f81343529957603734bc29453ae9513eb5e19a87425adb8975c621357c7caa0f353e06367cc186230adb28f75ae48330a58ba904854415bc118c8573f71566a0 SHA512 e7873ae34aed13e8f4d5709fede763552c28528e853ad02ee4a4377c043f1ce2ae5f7fc3e831ea1dc65f5a1c0a5ddded93b451258b539ed72b0e1c196676a677

diff --git a/sys-power/bbswitch/bbswitch-0.8_p20211129.ebuild b/sys-power/bbswitch/bbswitch-0.8_p20211129.ebuild
new file mode 100644
index 000000000000..409b02bf015a
--- /dev/null
+++ b/sys-power/bbswitch/bbswitch-0.8_p20211129.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-mod toolchain-funcs
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Bumblebee-Project/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	COMMIT="23891174a80ea79c7720bcc7048a5c2bfcde5cd9"
+	SRC_URI="https://github.com/Bumblebee-Project/bbswitch/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/bbswitch-${COMMIT}"
+fi
+
+DESCRIPTION="Toggle discrete NVIDIA Optimus graphics card"
+HOMEPAGE="https://github.com/Bumblebee-Project/bbswitch"
+
+SLOT="0"
+LICENSE="GPL-3+"
+IUSE=""
+
+DEPEND="
+	virtual/linux-sources
+	sys-kernel/linux-headers
+"
+RDEPEND=""
+
+MODULE_NAMES="bbswitch(acpi)"
+
+pkg_setup() {
+	linux-mod_pkg_setup
+
+	BUILD_TARGETS="default"
+	BUILD_PARAMS="KVERSION=${KV_FULL} CC=$(tc-getCC)"
+}
+
+src_prepare() {
+	# Fix build failure, bug #513542 and bug #761370
+	sed "s%^KDIR :=.*%KDIR := ${KV_OUT_DIR:-$KERNEL_DIR}%g" -i Makefile || die
+
+	default
+}
+
+src_install() {
+	einstalldocs
+
+	insinto /etc/modprobe.d
+	newins "${FILESDIR}"/bbswitch.modprobe bbswitch.conf
+
+	linux-mod_src_install
+}