[gentoo-commits] repo/gentoo:master commit in: app-admin/mcelog/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     5e2aa924b7bd44ff18f27b0b660ccfafec0049de
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 15 19:09:55 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Wed Dec 15 19:09:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e2aa924

app-admin/mcelog: fix python usage

Closes: https://bugs.gentoo.org/828940
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 app-admin/mcelog/mcelog-180-r1.ebuild | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/app-admin/mcelog/mcelog-180-r1.ebuild b/app-admin/mcelog/mcelog-180-r1.ebuild
new file mode 100644
index 000000000000..36d6a1697fe6
--- /dev/null
+++ b/app-admin/mcelog/mcelog-180-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=(python3_9 python3_10)
+
+inherit linux-info python-any-r1 systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch
+	eapply_user
+	tc-export CC
+	python_fix_shebang genconfig.py
+}
+
+src_install() {
+	default
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit ${PN}.service
+
+	dodoc *.pdf
+}