[gentoo-commits] repo/gentoo:master commit in: sys-libs/libosinfo/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     712522e660a58e8c4889c6c23c930e90a594b988
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 01:38:53 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun Nov 28 19:54:07 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=712522e6

sys-libs/libosinfo: migrate to hwdata

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 sys-libs/libosinfo/libosinfo-1.9.0-r1.ebuild | 60 ++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/sys-libs/libosinfo/libosinfo-1.9.0-r1.ebuild b/sys-libs/libosinfo/libosinfo-1.9.0-r1.ebuild
new file mode 100644
index 000000000000..54ada71ed302
--- /dev/null
+++ b/sys-libs/libosinfo/libosinfo-1.9.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit meson udev vala xdg
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="https://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="gtk-doc +introspection +vala test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	net-libs/libsoup:2.4
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwdata
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+"
+DEPEND="${RDEPEND}"
+# perl dep is for pod2man for automagic manpage building
+BDEPEND="
+	dev-lang/perl
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_feature introspection enable-introspection)
+		$(meson_use test enable-tests)
+		$(meson_feature vala enable-vala)
+		-Dwith-pci-ids-path="${EPREFIX}"/usr/share/hwdata/pci.ids
+		-Dwith-usb-ids-path="${EPREFIX}"/usr/share/hwdata/usb.ids
+	)
+	meson_src_configure
+}