From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1343890-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id ED439158086
for <garchives@archives.gentoo.org>; Sat, 27 Nov 2021 21:18:33 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 22DCE2BC030;
Sat, 27 Nov 2021 21:18:32 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id E39FA2BC030
for <gentoo-commits@lists.gentoo.org>; Sat, 27 Nov 2021 21:18:31 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id DB18B343111
for <gentoo-commits@lists.gentoo.org>; Sat, 27 Nov 2021 21:18:30 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 266F41E6
for <gentoo-commits@lists.gentoo.org>; Sat, 27 Nov 2021 21:18:29 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1638047904.d1273bd4cfd3ff4722c0b356dd81629ba705185d.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/sphinx/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/sphinx/Manifest dev-python/sphinx/sphinx-4.3.1.ebuild
X-VCS-Directories: dev-python/sphinx/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: d1273bd4cfd3ff4722c0b356dd81629ba705185d
X-VCS-Branch: master
Date: Sat, 27 Nov 2021 21:18:29 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 0e647e82-7b0c-4d2f-8a4a-d3f7e2b2fba4
X-Archives-Hash: 2428bb6d58556b372ab2c1b6a8240059
commit: d1273bd4cfd3ff4722c0b356dd81629ba705185d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 27 20:17:34 2021 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov 27 21:18:24 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1273bd4
dev-python/sphinx: Bump to 4.3.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-4.3.1.ebuild | 129 ++++++++++++++++++++++++++++++++++
2 files changed, 130 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 7d9f035754b0..c23da342a7d0 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,3 +1,4 @@
DIST Sphinx-3.5.4.tar.gz 5911093 BLAKE2B 8740714dfaf3733bf57d0b277315b4e7b5cad86247ea30dcbc4f5dadf5f5169329050b7be43ec8625c47df9dcc19afcc6c4d782725c7007f8178b7eb7be7dc05 SHA512 853379f3b0496772846be9beb072c2c8a69ff899ffe4c6435b448ea639a32138c61403f9c14f62f4f78b2e526a2ee7c05b4196eabdeee37bcae6aa98df992125
DIST Sphinx-4.2.0.tar.gz 6503692 BLAKE2B a3cc73c215be6859f285b92d651f2fe60f731340e7c003d3b275247593d1e641a25618817f67e7f3d8767724d6e98a6d63493bea340c7171e4e3da384da776e2 SHA512 6c6a2424362805b758c43136a9293dcfb02d45af6e6dc2dd7ed9382f6ae04ecfbd416efeecb42219b67d026a4a0b007500e87b20d81847ab48e2ccfcdca52e75
DIST Sphinx-4.3.0.tar.gz 6657624 BLAKE2B 6bd2b2a1b1d84e8da07676cd820c7db793e60649c6d2336f5fe0347e1ffaf1cfeb2e376f480f2f83f1745c1bd7325b482d312ae4446735052defcfa0e74ad09d SHA512 ba3463135dc578024819d9c70b3707d4465c4a71aa305474f7b34b14e276ee491e029bb8bc93c05ed1463a6bc63a82e0507c16ede7046fd1216e31553027e449
+DIST Sphinx-4.3.1.tar.gz 6655951 BLAKE2B eacc9d39e1a108dba1f8d3bd96d7f78f1755f23233c8068dbe598f3d3539d9cf0ea9c12374e0ffc4f471004bbe7cbd6e80ebfa7bcfbf85e5d8c34ed4adfb2acb SHA512 0b7ceb369783d30685c10783fe10b58e92a2f5ae50dda1b6cfb021b0d33fb424a2c6cddc6b97018b63347127fc74ed4f7a442c312ce9e75ceb537f127a46bb9d
diff --git a/dev-python/sphinx/sphinx-4.3.1.ebuild b/dev-python/sphinx/sphinx-4.3.1.ebuild
new file mode 100644
index 000000000000..c54c5794ced7
--- /dev/null
+++ b/dev-python/sphinx/sphinx-4.3.1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+ <dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+ >=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.18[${PYTHON_USEDEP}]
+ dev-python/imagesize[${PYTHON_USEDEP}]
+ >=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )"
+BDEPEND="
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ virtual/imagemagick-tools[jpeg,png,svg]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-3.2.1-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ # remove unnecessary upper bounds
+ sed -e '/Jinja2/s:,<3.0::' \
+ -e '/MarkupSafe/s:<2.0::' \
+ -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ distutils-r1_python_compile
+
+ # Generate the grammar. It will be caught by install somehow.
+ # Note that the tests usually do it for us. However, I don't want
+ # to trust USE=test really running all the tests, especially
+ # with FEATURES=test-fail-continue.
+ pushd "${BUILD_DIR}"/lib >/dev/null || die
+ "${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+ popd >/dev/null || die
+}
+
+python_compile_all() {
+ if use doc; then
+ esetup.py build_sphinx
+ HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+ fi
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ local deselect=(
+ # these tests require Internet access
+ tests/test_build_latex.py::test_latex_images
+ tests/test_build_linkcheck.py::test_defaults
+ tests/test_build_linkcheck.py::test_defaults_json
+ tests/test_build_linkcheck.py::test_anchors_ignored
+ )
+ [[ ${EPYTHON} == pypy3 ]] && deselect+=(
+ tests/test_build_linkcheck.py::test_connect_to_selfsigned_fails
+ tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+ tests/test_ext_autodoc.py::test_autodoc_typed_inherited_instance_variables
+ tests/test_ext_autodoc.py::test_autodoc_typed_instance_variables
+ tests/test_ext_autodoc.py::test_automethod_for_builtin
+ tests/test_ext_autodoc.py::test_cython
+ tests/test_ext_autodoc.py::test_partialfunction
+ tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+ tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+ tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+ tests/test_ext_autodoc_autodata.py::test_autodata_type_comment
+ tests/test_ext_autodoc_autofunction.py::test_builtin_function
+ tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+ tests/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+ tests/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+ tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+ tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+ tests/test_pycode_parser.py::test_annotated_assignment
+ )
+
+ epytest ${deselect[@]/#/--deselect }
+}