From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1337841-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits) server-digest SHA256)
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 9203F158086
for <garchives@archives.gentoo.org>; Tue, 9 Nov 2021 03:37:47 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 9C2FC2BC003;
Tue, 9 Nov 2021 03:37:46 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id EA04D2BC00D
for <gentoo-commits@lists.gentoo.org>; Tue, 9 Nov 2021 03:37:45 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8B10D342D88
for <gentoo-commits@lists.gentoo.org>; Tue, 9 Nov 2021 03:37:44 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id A71DA175
for <gentoo-commits@lists.gentoo.org>; Tue, 9 Nov 2021 03:37:42 +0000 (UTC)
From: "Michael Orlitzky" <mjo@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michael Orlitzky" <mjo@gentoo.org>
Message-ID: <1636429030.444b2094dad9c3f4b5eb82592997534eb2e472ed.mjo@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/ntl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-libs/ntl/ntl-11.4.4-r1.ebuild
X-VCS-Directories: dev-libs/ntl/
X-VCS-Committer: mjo
X-VCS-Committer-Name: Michael Orlitzky
X-VCS-Revision: 444b2094dad9c3f4b5eb82592997534eb2e472ed
X-VCS-Branch: master
Date: Tue, 9 Nov 2021 03:37:42 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 94856c2f-d5b5-44db-9b26-9dc7afad1ba3
X-Archives-Hash: d700650d89b8ba1ae531d6b48d9aeee1
commit: 444b2094dad9c3f4b5eb82592997534eb2e472ed
Author: Alex Fan <alexfanqi <AT> yahoo <DOT> com>
AuthorDate: Tue Nov 9 01:07:47 2021 +0000
Commit: Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Tue Nov 9 03:37:10 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=444b2094
dev-libs/ntl: add 11.4.4-r1
bump to EAPI 8
update bundled config.guess and config.sub automatically.
Closes: https://bugs.gentoo.org/821061
Closes: https://github.com/gentoo/gentoo/pull/22822
Signed-off-by: Alex Fan <alexfanqi <AT> yahoo.com>
Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>
dev-libs/ntl/ntl-11.4.4-r1.ebuild | 71 +++++++++++++++++++++++++++++++++++++++
1 file changed, 71 insertions(+)
diff --git a/dev-libs/ntl/ntl-11.4.4-r1.ebuild b/dev-libs/ntl/ntl-11.4.4-r1.ebuild
new file mode 100644
index 00000000000..1b184a8a48c
--- /dev/null
+++ b/dev-libs/ntl/ntl-11.4.4-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs gnuconfig
+
+DESCRIPTION="High-performance and portable C++ number theory library"
+HOMEPAGE="https://www.shoup.net/ntl/ https://github.com/libntl/ntl"
+SRC_URI="https://www.shoup.net/ntl/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/43"
+KEYWORDS="~amd64 ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="bindist doc static-libs threads cpu_flags_x86_avx2"
+
+BDEPEND="dev-lang/perl"
+DEPEND="dev-libs/gmp:0=
+ dev-libs/gf2x
+ threads? ( >=dev-libs/gf2x-1.2 )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P}/src"
+
+REQUIRED_USE="bindist? ( !cpu_flags_x86_avx2 )"
+
+DOCS=( "${WORKDIR}/${P}"/README )
+
+src_unpack() {
+ default
+ gnuconfig_update "${S}/libtool-origin/"
+}
+
+src_configure() {
+ # Currently the build system can build a static library or both
+ # static and shared libraries, but not only shared libraries. The
+ # name NTL_GMP_LIP is *not* a typo.
+ perl DoConfig \
+ PREFIX="${EPREFIX}"/usr \
+ LIBDIR="${EPREFIX}"/usr/$(get_libdir) \
+ CXXFLAGS="${CXXFLAGS}" \
+ CPPFLAGS="${CPPFLAGS}" \
+ LDFLAGS="${LDFLAGS}" \
+ CXX="$(tc-getCXX)" \
+ AR="$(tc-getAR)" \
+ RANLIB="$(tc-getRANLIB)" \
+ SHARED=on \
+ NTL_GMP_LIP=on \
+ NTL_GF2X_LIB=on \
+ NTL_THREADS=$(usex threads on off) \
+ NTL_ENABLE_AVX_FFT=$(usex cpu_flags_x86_avx2 on off) \
+ NATIVE=$(usex bindist off on) \
+ || die "DoConfig failed"
+
+ if use doc; then
+ DOCS+=( "${WORKDIR}/${P}"/doc/*.txt )
+ HTML_DOCS=( "${WORKDIR}/${P}"/doc/*.html "${WORKDIR}/${P}"/doc/*.gif )
+ fi
+}
+
+src_install() {
+ default
+
+ if ! use static-libs; then
+ # bug #775884
+ find "${ED}" -name '*.la' -delete || die
+ rm "${ED}/usr/$(get_libdir)"/libntl.a || die
+ fi
+
+ rm -r "${ED}"/usr/share/doc/NTL || die
+}