[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     23cbe73faa41b493d74411b34ed1f32c3976d2ca
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Wed Nov  3 01:34:15 2021 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Wed Nov  3 01:44:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23cbe73f

sys-apps/fwupd: bump to v1.7.1

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.7.1.ebuild | 176 ++++++++++++++++++++++++++++++++++++++
 sys-apps/fwupd/metadata.xml       |   3 +-
 3 files changed, 179 insertions(+), 1 deletion(-)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 576bc66efdd..9163bf9246a 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -3,3 +3,4 @@ DIST fwupd-1.6.2.tar.gz 3885963 BLAKE2B 183abc4d620b884a276dece39ad1e57f606c2237
 DIST fwupd-1.6.3.tar.gz 3888812 BLAKE2B 08d24fde80010d50e2396f59d743a00e640c1fcc06f6ada566ebcff48d25f1dc33676a40d13e1b684e45fd9483af1d9755ef3ac00bdaa8a37236589c03bb8a4c SHA512 837bcfe57873315ade8f3ff82d290d492dcb047387db5a642e6e7fc8e9ff7c3cabe5892692e2d4b5b0c5bd69f8a253bc364c61f23013c161a350b39de7d58e67
 DIST fwupd-1.6.4.tar.gz 3891113 BLAKE2B b4f3a629c0594ee69a0e2ea727c8080f63e970a6e9964b53d007e490d6b538f5441a65de20412673ded181611342c7c1c1ec16eb0d05c69c149f635fed325269 SHA512 d0c788313f8cf00c6e0e238436668ab5885133933cd74202d3eb4a3377d1b123689dd7f3827d45853c92b98196d5d896027b471117af461356e2f3c3ec82f58e
 DIST fwupd-1.7.0.tar.gz 4102985 BLAKE2B 9a29621e029c526d513304863294ee69f14ff1cf069b388fe5dc6037b2f030ea24136f18d9096abcc449376295996e3184c1c969f8dda329f2786622ba1300a7 SHA512 148f161f0e8d008fa20091c747baf4a205bc2e76ddc5dbb3676e3f2a15ca5d6d1454b572ea0336f185b5ef3a8ca8bfd3ad1098649e095a58c9822d4dbffe2987
+DIST fwupd-1.7.1.tar.gz 4025627 BLAKE2B 035796e8ebaafe139b8b6e7014f51c6e16a228d0ef697984f86e31c28f38aa62bc7d3bd64466b3f3c83c2605b229d7b3063287373c83ec4d962adca3c85cc6de SHA512 c695b66ebbe23908f5d6ef6d6084c092af8754e0677f094ee4d09b02d904f3f3cca0e460c5345a835c16b7303bba72209e216ba28285e44bce4872fffa136a5e

diff --git a/sys-apps/fwupd/fwupd-1.7.1.ebuild b/sys-apps/fwupd/fwupd-1.7.1.ebuild
new file mode 100644
index 00000000000..3d035a100b4
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.7.1.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit linux-info meson python-single-r1 vala xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="agent amt archive bluetooth dell elogind fastboot flashrom gnutls gtk-doc gusb introspection logitech lzma +man minimal modemmanager nvme policykit spi synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	dell? ( uefi )
+	fastboot? ( gusb )
+	logitech? ( gusb )
+	minimal? ( !introspection )
+	spi? ( lzma )
+	synaptics? ( gnutls )
+	uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.1.13:=[introspection?]
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	net-misc/curl
+	virtual/libelf:0=
+	virtual/udev
+	archive? ( app-arch/libarchive:= )
+	dell? ( >=sys-libs/libsmbios-2.4.0 )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( net-libs/gnutls )
+	gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
+	logitech? ( dev-libs/protobuf-c:= )
+	lzma? ( app-arch/xz-utils )
+	modemmanager? ( net-misc/modemmanager[qmi] )
+	policykit? ( >=sys-auth/polkit-0.103 )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss )
+	uefi? (
+		sys-apps/fwupd-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+	!<sci-chemistry/chemical-mime-data-0.1.94-r4
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use nvme ; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+
+	sed -e '/platform-integrity/d' \
+		-i plugins/meson.build || die #753521
+
+	sed -e "/install_dir.*'doc'/s/fwupd/${PF}/" \
+		-i data/builder/meson.build || die
+
+	vala_src_prepare
+}
+
+src_configure() {
+	local plugins=(
+		$(meson_use amt plugin_amt)
+		$(meson_use dell plugin_dell)
+		$(meson_use fastboot plugin_fastboot)
+		$(meson_use flashrom plugin_flashrom)
+		$(meson_use gusb plugin_altos)
+		$(meson_use logitech plugin_logitech_bulkcontroller)
+		$(meson_use modemmanager plugin_modem_manager)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use spi plugin_intel_spi)
+		$(meson_use synaptics plugin_synaptics_mst)
+		$(meson_use synaptics plugin_synaptics_rmi)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use tpm plugin_tpm)
+		$(meson_use uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+		$(meson_use uefi plugin_uefi_pk)
+	)
+	use ppc64 && plugins+=( -Dplugin_msr="false" )
+	use riscv && plugins+=( -Dplugin_msr="false" )
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Dconsolekit="false"
+		-Dcurl="true"
+		-Ddocs="$(usex gtk-doc gtkdoc none)"
+		-Defi_binary="false"
+		-Dsupported_build="true"
+		$(meson_use agent)
+		$(meson_use archive libarchive)
+		$(meson_use bluetooth bluez)
+		$(meson_use elogind)
+		$(meson_use gnutls)
+		$(meson_use gusb)
+		$(meson_use lzma)
+		$(meson_use man)
+		$(meson_use introspection)
+		$(meson_use policykit polkit)
+		$(meson_use systemd)
+		$(meson_use test tests)
+
+		${plugins[@]}
+	)
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}

diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index d1dfe55c1e5..09178d3fd15 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -13,7 +13,8 @@
 		<flag name="agent">Enable update notification agent</flag>
 		<flag name="archive">Use <pkg>app-arch/libarchive</pkg> for archives support</flag>
 		<flag name="amt">Build and install Intel AMT plugin</flag>
-		<flag name="dell">Enable Dell-specific support.</flag>
+		<flag name="dell">Enable Dell-specific support</flag>
+		<flag name="fastboot">Build and install fastboot plugin</flag>
 		<flag name="flashrom">Enable flashrom plugin via <pkg>sys-apps/flashrom</pkg></flag>
 		<flag name="gusb">Enable <pkg>dev-libs/libgusb</pkg> support</flag>
 		<flag name="logitech">Build and install Logitech bulk controller plugin</flag>