From: "Alfredo Tupone" <tupone@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-tcltk/tix/
Date: Tue, 26 Oct 2021 19:18:33 +0000 (UTC) [thread overview]
Message-ID: <1635275897.1a96067b27c453b3d35dbdc837fc14aa4904cd9b.tupone@gentoo> (raw)
commit: 1a96067b27c453b3d35dbdc837fc14aa4904cd9b
Author: Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 26 19:18:17 2021 +0000
Commit: Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Tue Oct 26 19:18:17 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a96067b
dev-tcltk/tix: EAPI 8
Closes: https://bugs.gentoo.org/819588
Closes: https://bugs.gentoo.org/806282
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>
dev-tcltk/tix/tix-8.4.3-r2.ebuild | 69 +++++++++++++++++++++++++++++++++++++++
1 file changed, 69 insertions(+)
diff --git a/dev-tcltk/tix/tix-8.4.3-r2.ebuild b/dev-tcltk/tix/tix-8.4.3-r2.ebuild
new file mode 100644
index 00000000000..778b6224634
--- /dev/null
+++ b/dev-tcltk/tix/tix-8.4.3-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="Tix${PV}"
+DESCRIPTION="A widget library for Tcl/Tk"
+HOMEPAGE="http://tix.sourceforge.net/"
+SRC_URI="mirror://sourceforge/tix/${MY_P}-src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RESTRICT="test"
+
+DEPEND="
+ dev-lang/tk:0=
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-libs/libXdmcp"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-tcl8.5.patch
+ "${FILESDIR}"/${P}-tcl8.6.patch
+)
+
+src_prepare() {
+ [[ ${CHOST} == *-darwin* ]] || eapply "${FILESDIR}"/${P}-link.patch
+
+ sed \
+ -e 's:-Os::g' \
+ -i configure tclconfig/tcl.m4 || die
+ default
+}
+
+src_configure() {
+ econf \
+ --with-tcl="${EPREFIX}/usr/$(get_libdir)" \
+ --with-tk="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+ DOCS=( ChangeLog README.txt docs/*.txt )
+ HTML_DOCS=(
+ index.html
+ ABOUT.html
+ docs/*.html
+ docs/html
+ docs/img
+ docs/tix-book
+ )
+
+ default
+
+ # Bug #168897
+ doheader generic/tix.h
+
+ # Bug #201138
+ if [[ ${CHOST} == *-darwin* ]] ; then
+ mv "${ED}"/usr/$(get_libdir)/${MY_P}/libTix{,.}${PV}.dylib || die
+ dosym ${MY_P}/libTix.${PV}.dylib /usr/$(get_libdir)/libTix.${PV}.dylib
+ else
+ dosym ${MY_P}/lib${MY_P}.so /usr/$(get_libdir)/lib${MY_P}.so
+ fi
+}
next reply other threads:[~2021-10-26 19:18 UTC|newest]
Thread overview: 17+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-10-26 19:18 Alfredo Tupone [this message]
-- strict thread matches above, loose matches on Subject: below --
2023-03-11 21:52 [gentoo-commits] repo/gentoo:master commit in: dev-tcltk/tix/ Alfredo Tupone
2022-12-26 2:03 WANG Xuerui
2022-01-02 11:22 Jakov Smolić
2022-01-02 0:04 Sam James
2022-01-01 11:07 Sam James
2021-12-30 19:48 Arthur Zamarin
2021-12-28 20:46 Arthur Zamarin
2021-12-28 20:39 Arthur Zamarin
2021-12-28 20:39 Arthur Zamarin
2021-12-28 20:39 Arthur Zamarin
2021-06-30 17:55 Marek Szuba
2021-01-07 8:20 Fabian Groffen
2021-01-06 22:33 Fabian Groffen
2020-06-04 17:14 Mart Raudsepp
2018-06-08 7:56 Mikle Kolyada
2017-06-21 10:27 Alexis Ballier
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1635275897.1a96067b27c453b3d35dbdc837fc14aa4904cd9b.tupone@gentoo \
--to=tupone@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox