[gentoo-commits] repo/gentoo:master commit in: media-video/handbrake/

["Sam James" <sam@gentoo.org>]

commit:     38720deacdda9f4cc2802eafdad04b1c48e73e31
Author:     James Beddek <telans <AT> posteo <DOT> de>
AuthorDate: Sun Oct 24 08:20:19 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Oct 24 08:21:47 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38720dea

media-video/handbrake: sync live

Signed-off-by: James Beddek <telans <AT> posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/22693
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-video/handbrake/handbrake-9999.ebuild | 83 ++++++++++++++---------------
 1 file changed, 39 insertions(+), 44 deletions(-)

diff --git a/media-video/handbrake/handbrake-9999.ebuild b/media-video/handbrake/handbrake-9999.ebuild
index a0fb6014561..ccc9b241fcf 100644
--- a/media-video/handbrake/handbrake-9999.ebuild
+++ b/media-video/handbrake/handbrake-9999.ebuild
@@ -1,10 +1,11 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{7,8,9} )
-inherit autotools gnome2-utils python-any-r1 xdg-utils
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools python-any-r1 xdg
 
 if [[ ${PV} = *9999* ]]; then
 	EGIT_REPO_URI="https://github.com/HandBrake/HandBrake.git"
@@ -17,7 +18,7 @@ else
 fi
 
 DESCRIPTION="Open-source, GPL-licensed, multiplatform, multithreaded video transcoder"
-HOMEPAGE="http://handbrake.fr/"
+HOMEPAGE="https://handbrake.fr/ https://github.com/HandBrake/HandBrake"
 
 LICENSE="GPL-2"
 SLOT="0"
@@ -27,25 +28,26 @@ REQUIRED_USE="^^ ( fdk libav-aac )"
 
 RDEPEND="
 	app-arch/xz-utils
-	media-libs/speex
 	dev-libs/jansson:=
 	dev-libs/libxml2
 	media-libs/a52dec
+	>=media-libs/dav1d-0.5.1
 	media-libs/libass:=
 	>=media-libs/libbluray-1.0
-	>=media-libs/dav1d-0.5.1
 	media-libs/libdvdnav
 	media-libs/libdvdread:=
 	media-libs/libsamplerate
 	media-libs/libtheora
 	media-libs/libvorbis
 	>=media-libs/libvpx-1.8
-	nvenc? ( media-libs/nv-codec-headers )
 	media-libs/opus
+	media-libs/speex
 	media-libs/x264:=
+	media-libs/zimg
 	media-sound/lame
-	sys-libs/zlib
 	>=media-video/ffmpeg-4.2.1:0=[postproc,fdk?]
+	sys-libs/zlib
+	fdk? ( media-libs/fdk-aac )
 	gstreamer? (
 		media-libs/gstreamer:1.0
 		media-libs/gst-plugins-base:1.0
@@ -67,13 +69,15 @@ RDEPEND="
 		x11-libs/libnotify
 		x11-libs/pango
 	)
-	fdk? ( media-libs/fdk-aac )
-	x265? ( >=media-libs/x265-3.2:0=[10bit,12bit,numa?] )"
-
-DEPEND="${RDEPEND}
+	nvenc? ( media-libs/nv-codec-headers )
+	x265? ( >=media-libs/x265-3.2:0=[10bit,12bit,numa?] )
+"
+DEPEND="
 	${PYTHON_DEPS}
+	${RDEPEND}
 	dev-lang/nasm
-	dev-util/intltool"
+	dev-util/intltool
+"
 
 PATCHES=(
 	# Remove libdvdnav duplication and call it on the original instead.
@@ -83,6 +87,9 @@ PATCHES=(
 	# Remove faac dependency; TODO: figure out if we need to do this at all.
 	"${FILESDIR}/${PN}-9999-remove-faac-dependency.patch"
 
+	# Detect system tools - bug 738110
+	"${FILESDIR}/${PN}-9999-system-tools.patch"
+
 	# Use whichever python is set by portage
 	"${FILESDIR}/${PN}-1.3.0-dont-search-for-python.patch"
 
@@ -98,9 +105,7 @@ src_prepare() {
 
 	default
 
-	cd "${S}/gtk"
-	# Don't run autogen.sh.
-	sed -i '/autogen.sh/d' module.rules || die "Removing autogen.sh call failed"
+	cd "${S}/gtk" || die
 	eautoreconf
 }
 
@@ -108,35 +113,31 @@ src_configure() {
 	# Libav was replaced in 1.2 with ffmpeg by default
 	# but I've elected to not make people change their use flags for AAC
 	# as its the same code anyway
-	./configure \
-		--force \
-		--verbose \
-		--prefix="${EPREFIX}/usr" \
-		--disable-gtk-update-checks \
-		--disable-flatpak \
-		--disable-gtk4 \
-		$(use_enable libav-aac ffmpeg-aac) \
-		$(use_enable fdk fdk-aac) \
-		$(usex !gtk --disable-gtk) \
-		$(usex !gstreamer --disable-gst) \
-		$(use_enable numa) \
-		$(use_enable nvenc) \
-		$(use_enable x265) || die "Configure failed."
+	local myconfargs=(
+		--force
+		--verbose
+		--prefix="${EPREFIX}/usr"
+		--disable-gtk-update-checks
+		--disable-flatpak
+		--disable-gtk4
+		$(use_enable libav-aac ffmpeg-aac)
+		$(use_enable fdk fdk-aac)
+		$(usex !gtk --disable-gtk)
+		$(usex !gstreamer --disable-gst)
+		$(use_enable numa)
+		$(use_enable nvenc)
+		$(use_enable x265)
+	)
+	
+	./configure "${myconfargs[@]}" || die "Configure failed."
 }
 
 src_compile() {
 	emake -C build
-
-	# TODO: Documentation building is currently broken, try to fix it.
-	#
-	# if use doc ; then
-	# 	emake -C build doc
-	# fi
 }
 
 src_install() {
 	emake -C build DESTDIR="${D}" install
-
 	dodoc README.markdown AUTHORS.markdown NEWS.markdown THANKS.markdown
 }
 
@@ -152,11 +153,5 @@ pkg_postinst() {
 		einfo "For the GTK+ version of HandBrake, you can run \`ghb\`."
 	fi
 
-	xdg_icon_cache_update
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_desktop_database_update
+	xdg_pkg_postinst
 }