From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1332017-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 86A37158086
for <garchives@archives.gentoo.org>; Wed, 20 Oct 2021 02:42:39 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id C78B5E0831;
Wed, 20 Oct 2021 02:42:38 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 97390E0831
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Oct 2021 02:42:38 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 6B50534390F
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Oct 2021 02:42:37 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id E3F22172
for <gentoo-commits@lists.gentoo.org>; Wed, 20 Oct 2021 02:42:34 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1634695801.f842ea5c7f58b862c66016b1550514b82580dcfe.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/hydrus/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-gfx/hydrus/Manifest media-gfx/hydrus/hydrus-458.ebuild
X-VCS-Directories: media-gfx/hydrus/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: f842ea5c7f58b862c66016b1550514b82580dcfe
X-VCS-Branch: master
Date: Wed, 20 Oct 2021 02:42:34 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: e9aba161-3302-4b05-a8cb-8a5b08711267
X-Archives-Hash: 8d9d85e3a1b1e27e16c94ac0de73ac37
commit: f842ea5c7f58b862c66016b1550514b82580dcfe
Author: Ekaterina Vaartis <vaartis <AT> kotobank <DOT> ch>
AuthorDate: Sat Oct 16 16:46:49 2021 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct 20 02:10:01 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f842ea5c
media-gfx/hydrus: Add 458
Signed-off-by: Ekaterina Vaartis <vaartis <AT> kotobank.ch>
Closes: https://github.com/gentoo/gentoo/pull/22540
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-gfx/hydrus/Manifest | 1 +
media-gfx/hydrus/hydrus-458.ebuild | 139 +++++++++++++++++++++++++++++++++++++
2 files changed, 140 insertions(+)
diff --git a/media-gfx/hydrus/Manifest b/media-gfx/hydrus/Manifest
index e3fb9ae9607..5329bab5b60 100644
--- a/media-gfx/hydrus/Manifest
+++ b/media-gfx/hydrus/Manifest
@@ -1,3 +1,4 @@
DIST hydrus-454.tar.gz 38886940 BLAKE2B 38fe5b3483c13dfbf82e636be1e743bb6af6f340a86d5ea69f0e71f7452cd3506b076cf4d6f460e0a1896f0839be7494028a0cbb5f567001af025cd436cf5c45 SHA512 87971c45bc11e7eaba2e08255ca23600406124bd73d6d8d4800ec67135a0d74b5ca7fc8a8a159dbdc89f70702760469c8d719de11f5bf943f7679978a790c456
DIST hydrus-456.tar.gz 38899003 BLAKE2B 03e575034f2b4234c7f9ed3d4da59a3f94e9e2871440548b192b0898fa7e5d73bf7ab07f91a380db6e884449d6d86df9aed313238f28e1b3c4d7ae4a8f7f00f4 SHA512 de16874aa714a7e3640a9673a1445049256a2a05122f57a8646fd375a295f229c8b262e8c7862bbc7257d8db84a9e4ddf03cf841af307bed30e174e8f159508a
DIST hydrus-457.tar.gz 38915780 BLAKE2B 56506ba2098198f42593a061a79f7f6521597f057d87c07eb66b3a213111a46caaf1e167e9f49deaf3d3ffe6259105b6d19cca8fb8fbd0d1c708d796eea63394 SHA512 2a653f69928f4b65cdde332e7be52861527237a284a61ddd0536b6e1db40f91424e78953910dacf494d947a57086cbfbf9588fe638143f386910fb1d7ba1e484
+DIST hydrus-458.tar.gz 38922758 BLAKE2B 3339e44498a606664cd54357cf285f96eb4f146673d9991b9b0fb82bc961b31f4f47c9f27616251b610c4e28664a6b4753aa99713e50d93e79121270796b1408 SHA512 0f2c419012c683c163fd180662eb9d2eb5610a6d87c0cbd42be91dbdf6101e747ba0c6238d1574084a30d1da1c7546a79b0e648fe55420c510d47ab26fad28c3
diff --git a/media-gfx/hydrus/hydrus-458.ebuild b/media-gfx/hydrus/hydrus-458.ebuild
new file mode 100644
index 00000000000..0915a2ae543
--- /dev/null
+++ b/media-gfx/hydrus/hydrus-458.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 desktop optfeature
+
+DESCRIPTION="A booru-like media organizer for the desktop"
+HOMEPAGE="https://hydrusnetwork.github.io/hydrus/ https://github.com/hydrusnetwork/hydrus"
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/hydrusnetwork/hydrus.git"
+else
+ SRC_URI="https://github.com/hydrusnetwork/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+ KEYWORDS="~amd64"
+fi
+
+# hydrus itself is WTFPL
+# icons included are CC-BY-2.5
+LICENSE="WTFPL-2 CC-BY-2.5"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+# RDEPEND is sorted as such:
+# - No specific requirements
+# - Specific version or slot
+RDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/cloudscraper[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/pyside2[widgets,gui,${PYTHON_USEDEP}]
+ dev-python/python-mpv[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/send2trash[${PYTHON_USEDEP}]
+ dev-python/service_identity[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/twisted[${PYTHON_USEDEP}]
+ media-libs/opencv[python,png,jpeg,${PYTHON_USEDEP}]
+ media-video/ffmpeg
+ media-video/mpv[libmpv,${PYTHON_USEDEP}]
+
+ >=dev-python/QtPy-1.9.0-r4[pyside2,${PYTHON_USEDEP}]
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ ')
+"
+BDEPEND="
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ test? (
+ dev-python/httmock[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ )
+ ')
+"
+
+PATCHES=(
+ "${FILESDIR}/userpath-in-local-share.patch"
+)
+
+src_prepare() {
+ default
+
+ # Contains pre-built binaries for other systems and a broken swf renderer for linux
+ rm -r bin/ || die
+ # Build files used for CI, not actually needed
+ rm -r static/build_files || die
+ # Duplicate license file, not needed
+ rm license.txt || die
+ # Python requirements files, not needed
+ rm requirements_*.txt || die
+}
+
+src_compile() {
+ python_optimize "${S}"
+}
+
+src_test() {
+ # The tests use unittest, but are run with a custom runner script.
+ # QT_QPA_PLATFORM is required to make them run without X
+ local -x QT_QPA_PLATFORM=offscreen
+ "${EPYTHON}" "${S}/test.py" || die "Tests failed"
+}
+
+src_install() {
+ local doc="${EPREFIX}/usr/share/doc/${PF}"
+ elog "Hydrus includes an excellent manual, that can either be viewed at"
+ elog "${doc}/html/help/index.html"
+ elog "or accessed through the hydrus help menu."
+
+ mv "help my client will not boot.txt" "help_my_client_will_not_boot.txt" || die
+
+ local DOCS=(COPYING README.md Readme.txt help_my_client_will_not_boot.txt db/)
+ local HTML_DOCS=("${S}"/help/)
+ einstalldocs
+
+ # Files only needed for testing
+ rm test.py hydrus/hydrus_test.py || die
+ rm -r hydrus/test/ static/testing/ || die
+
+ # These files are copied into doc
+ rm -r "${DOCS[@]}" "${HTML_DOCS[@]}" || die
+ # The program expects to find documentation here, so add a symlink to doc
+ dosym "${doc}/html/help" /opt/hydrus/help
+
+ insinto /opt/hydrus
+ doins -r "${S}"/.
+
+ exeinto /usr/bin
+ python_newexe - hydrus-server < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-server" || die)
+ python_newexe - hydrus-client < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-client" || die)
+
+ make_desktop_entry "hydrus-client" "Hydrus Client" "/opt/hydrus/static/hydrus_non-transparent.png" \
+ "AudioVideo;FileTools;Graphics;Network;"
+}
+
+pkg_postinst() {
+ optfeature "automatic port forwarding support" "net-libs/miniupnpc"
+ optfeature "bandwidth charts support" "dev-python/pyside2[charts]"
+ optfeature "memory compression in the client" "dev-python/lz4"
+ optfeature "SOCKS proxy support" "dev-python/requests[socks5]" "dev-python/PySocks"
+}