[gentoo-commits] repo/gentoo:master commit in: net-misc/gsutil/

["Mike Frysinger" <vapier@gentoo.org>]

commit:     038efd2c26384545b242a89a0c71e0b2a189ae59
Author:     Mike Frysinger <vapier <AT> chromium <DOT> org>
AuthorDate: Fri Oct 15 02:10:26 2021 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Fri Oct 15 02:10:44 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=038efd2c

net-misc/gsutil: version bump to 4.68

Signed-off-by: Mike Frysinger <vapier <AT> gentoo.org>

 net-misc/gsutil/Manifest           |  1 +
 net-misc/gsutil/gsutil-4.68.ebuild | 97 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/net-misc/gsutil/Manifest b/net-misc/gsutil/Manifest
index 465ad363d05..b939cc4aba9 100644
--- a/net-misc/gsutil/Manifest
+++ b/net-misc/gsutil/Manifest
@@ -1 +1,2 @@
 DIST gsutil_4.60.tar.gz 4012900 BLAKE2B d3d1b57d5b0d42b1b454944efe8d62855b665d3772817c636568ef49c79ae2c566ef08c4c6e1bd3c9829471561865b64b3beec8d3911d6766748337aa1b1fc3e SHA512 18ab701cbb60513d66e8b96ced28cfe65dc0f210435fb5ffbcbfab3541ec7ed051db726e52239796d9579d0928953f610064279a3ee1e5b5c06cec963493804c
+DIST gsutil_4.68.tar.gz 4459899 BLAKE2B 9855d379ba0483f1a33e4e05546444ff492c72d241ff0e5ca4f6c798c91b0c8d729247bf5fbaa39c411eb7a7e3f1fa701363898b903ba11c1bdf41c7e969c44d SHA512 b4af124808f34b5c0aa1d31b6d1bdbdeb451d39a246d4f2876ef664b6b485cdc5dc63bc3992ca4b7b33c72a00fc5119b931625e2c3230970bf0baa6389715e39

diff --git a/net-misc/gsutil/gsutil-4.68.ebuild b/net-misc/gsutil/gsutil-4.68.ebuild
new file mode 100644
index 00000000000..e907dba1478
--- /dev/null
+++ b/net-misc/gsutil/gsutil-4.68.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="command line tool for interacting with cloud storage services"
+HOMEPAGE="https://github.com/GoogleCloudPlatform/gsutil"
+SRC_URI="http://commondatastorage.googleapis.com/pub/${PN}_${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/boto-2.49.0[${PYTHON_USEDEP}]
+	>=dev-python/crcmod-1.7[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+	>=dev-python/gcs-oauth2-boto-plugin-2.7[${PYTHON_USEDEP}]
+	>=dev-python/google-apitools-0.5.32[${PYTHON_USEDEP}]
+	>=dev-python/google-reauth-python-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.18[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/gsutil-4.41-tests.patch"
+	"${FILESDIR}/gsutil-4.50-boto-tests.patch"
+	"${FILESDIR}/gsutil-4.50-tests.patch"
+)
+
+S="${WORKDIR}/${PN}"
+
+DOCS=( README.md CHANGES.md )
+
+# Needs to talk to Google to run tests.
+RESTRICT+=" test"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# NB: We don't delete all of boto/ because the tests are imported by the
+	# production code.  The same reason we can't delete gslib/tests/.  We can
+	# delete the main boto library and use the system version though.
+	rm -r gslib/vendored/boto/boto test || die
+
+	# Fails to compile with py3.
+	rm gslib/vendored/boto/tests/mturk/cleanup_tests.py || die
+
+	# monotonic is only used by bundled fasteners that we do not install.
+	sed -i \
+		-e 's/mock==/mock>=/' \
+		-e '/monotonic/d' \
+		setup.py || die
+	# Sanity check we didn't miss any updates.
+	grep '==' setup.py && die "Need to update version requirements"
+
+	# For debugging purposes, temporarily uncomment this in order to
+	# show hidden tracebacks.
+	#sed -e 's/^  except OSError as e:$/&\n    raise/' \
+	#	-e 's/def _HandleUnknownFailure(e):/&\n  raise/' \
+	#	-i gslib/__main__.py || die
+
+	# create_bucket raised ResponseNotReady.
+	sed -i \
+		-e 's/test_cp_unwritable_tracker_file/_&/' \
+		-e 's/test_cp_unwritable_tracker_file_download/_&/' \
+		gslib/tests/test_cp.py || die
+
+	sed -i -E -e 's/(executable_prefix =).*/\1 [sys.executable]/' \
+		gslib/commands/test.py || die
+
+	# IOError: close() called during concurrent operation on the same file object.
+	sed -i -e 's/sys.stderr.close()/#&/' \
+		gslib/tests/testcase/unit_testcase.py || die
+}
+
+python_compile() {
+	2to3 --write --nobackups --no-diffs -j "$(makeopts_jobs "${MAKEOPTS}" INF)" \
+		gslib/vendored/boto/tests || die "2to3 on boto tests failed"
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	BOTO_CONFIG="${FILESDIR}/dummy.boto" \
+		"${EPYTHON}" gslib/__main__.py test -u || die "tests failed with ${EPYTHON}"
+}