[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     4f81d4f96d8f7d7d159d915d0ffce72eae0520de
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  2 03:51:31 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Oct  2 03:51:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4f81d4f9

sys-kernel/gentoo-kernel-bin: add 5.10.70-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.70-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 63e7b48138e..c128c8d8be0 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -25,6 +25,7 @@ DIST gentoo-kernel-5.10.69-1.amd64.xpak 65520787 BLAKE2B a96f97152bb31b016e2d4a0
 DIST gentoo-kernel-5.10.69-1.arm64.xpak 61267801 BLAKE2B 466e762a98ec117fb32016ac9c6b16b1a78d784031b82194341c9787c0e42599cbace2452647f1c9146e0b90b56d2b8c6d458d9dbb6609cedc03059362b5b17e SHA512 c42443160b31bb5b705cba5e75742ff097ffd1f3e7956294ed6b2104ace2521008fac91c5a7882c13600b9759e0e996a88ffef6b8965b42ea313085213f6038a
 DIST gentoo-kernel-5.10.69-1.x86.xpak 57234909 BLAKE2B 2bc547a9370383560c151ee1a8a16e74e2202c1a7bf6877119a1ad1fa6776cb5fdd4c3ab6a711ef9d74e2790564593e9dfce9662ac788454a961026cbce7d1cf SHA512 7380a5a2db05fedf934383dd2fb85ca6e3909ebe8576abaae47e734cd4989d6c6fbdabd47062edb64c79b552831159801d1e1897972263f6adf42ad2c9d99171
 DIST gentoo-kernel-5.10.70-1.amd64.xpak 65517948 BLAKE2B 27a3f7686c27021a535f47bf1ff7660e94f04151fcc3fa6a33be30f86ed0ddf82e1e8e33c813db6ba1c7f10514c49e9ed0e4908940af09a5934c4a03bdc6697a SHA512 7db9b9b994b8fc09668704dd7922905226ec3da4f25debdd6b871cd1461cf4ff98b54a71650b7261604f7cd7614c75e894f5eaa00d8fe4d40279a720a0747d27
+DIST gentoo-kernel-5.10.70-1.arm64.xpak 61234933 BLAKE2B cd710e9461983633a92fa8cea7e48dd7d1fce7a46645b3589e6b2b7c38a66c6585be52d1be98e02f48cf2deb7327f6d0b9d0d3fc227da217f99d353a9a1c1336 SHA512 8d378db8b4eba00178876d139e4caf58ce4cc34b5d89d59622f20bda0b2dec7ae0f1bc20498dba24c004fa74df5dce2943efd5bcefc7eb356ba000dce742ceff
 DIST gentoo-kernel-5.10.70-1.x86.xpak 57241603 BLAKE2B 79dde6ba5c9ffb878267f491c304eba34ed7e64e82e6eb6c9076e61b9cc62e29effc7fd7b8a620272421af94b27fd378039ce4d8b7f9bd170faef298b4a7eb5e SHA512 42774c73aebb5844d796e85377f571a87cef2299b3081199de93c4e9bc63a6f19269b4a71b90a45c8c99a2d65a7fe1f61fc0101f3d130c4c01e3d49c24d6c062
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.70-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.70-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.70-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}